0

特定のスキーマ内のすべてのテーブルを調べる例外レポートを作成する必要があります。このレポートでは、列と行をカウントし、列ごとに NULL 値を含むエントリの数を一覧表示します。

カーソルを使用せずにこれを行うにはどうすればよいですか?

例：

People_Table には 3 つの列 (NAME、SURNAME、CONTACT_NO)
があります Entity_Table には 5 つの列 (ID、NAME、ADDRESS、TEL_NO、FAX_NO) があります

各テーブルと列の名前と、各列に NULL 値が含まれるレコードの数をリストする出力を生成する必要があります。

People_Table : NAME (4)、SURNAME (9)、CONTACT_NO (120)
Entity_Table : ID (0)、NAME (4)、ADDRESS (90)、TEL_NO (120)、FAX_NO (100)

出力は通常のデータセット形式にすることができ、エントリの連結のように見える必要はないことに注意してください! データ出力を説明するために、そのようにリストしただけです。

これは、この段階では NULL エントリを持たない列が将来 NULL エントリを持つ可能性があるため、時間の経過とともに変化する動的データベースのためのものです。そのため、これを追跡する必要があります。これまでのところ、このソリューションに向けて他のことを行ってきましたが、これが今必要なものの最後です。何かアドバイス？？

4

2 に答える 2

0

これを試してください（ただし、カーソルを使用します）：

DECLARE @tbl sysname
DECLARE @col sysname
DECLARE @sql nvarchar(max)
DECLARE @cnt INT

CREATE TABLE #result
(
    tbl sysname,
    col sysname,
    nulls int
)

DECLARE crs CURSOR FOR 
select t.name, c.name
from sys.columns c
join sys.tables t on c.object_id = t.object_id

OPEN crs

FETCH NEXT FROM crs INTO @tbl, @col

WHILE @@FETCH_STATUS=0
BEGIN

    SET @sql = 'select @cntOUT=count(*)  from '+@tbl+' where '+@col+' is null'

    SET @cnt = 0
    exec sp_executesql @sql, N'@cntOUT INT OUTPUT', @cntOUT=@cnt OUTPUT

    INSERT INTO #result (tbl, col, nulls)
    VALUES (@tbl, @col, @cnt)


    FETCH NEXT FROM crs INTO @tbl, @col
END

CLOSE crs
DEALLOCATE crs

SELECT * FROM #result

DROP TABLE #result
于 2013-02-28T14:57:11.883 に答える
0 
DECLARE @dbname VARCHAR(100) = 'dbname'
DECLARE @schemaName VARCHAR(100) = 'schemaname'
DECLARE @result TABLE ([NullValues] int,col VARCHAR(4000))

SELECT  @dbname dbname
        ,t.name tbl
        ,c.name col
INTO    #Temp1
FROM    sys.columns c
JOIN    sys.tables t ON 
        t.object_id = c.object_id
JOIN    sys.schemas s ON 
        s.schema_id = t.schema_id
WHERE   c.is_nullable = 1
AND     s.name in (@schemaName)

DECLARE @sql NVARCHAR(MAX) =
STUFF(
(
    SELECT  'UNION ALL SELECT Count(*) as [NullValues],''' + @dbname + '.' + @schemaName + '.' + tbl + '.' + col + ''' FROM ' + @dbname + '.' + @schemaName + '.' + tbl + ' WHERE ' + col + ' IS NULL '
    FROM    #Temp1
    FOR     XML PATH('')
), 1, 10, '   ')

INSERT @result
EXEC(@sql)

SELECT  [NullValues], col
INTO #Nulls
FROM    @result
WHERE   col IS NOT NULL AND [NullValues] > 0

SELECT
       [TABLE_CATALOG] + '.' + [TABLE_SCHEMA] + '.' + [TABLE_NAME] + '.' + [COLUMN_NAME] as SchemaTableColumn
      ,[TABLE_CATALOG] as 'Database'
      ,[TABLE_SCHEMA] as 'Schema'
      ,[TABLE_NAME] as 'TableName'
      ,[COLUMN_NAME]
      ,[ORDINAL_POSITION]
      ,[DATA_TYPE]
INTO #Temp2
  FROM [DW_LandingCR].[INFORMATION_SCHEMA].[COLUMNS]
  WHERE
    [TABLE_SCHEMA] = @schemaName
  ORDER BY TABLE_SCHEMA,TABLE_NAME,ORDINAL_POSITION

SELECT sc.name as [Schema],ta.name as [TableName],SUM(pa.rows) RowCnt
INTO #Temp3
 FROM sys.tables ta
 INNER JOIN sys.partitions pa
 ON pa.OBJECT_ID = ta.OBJECT_ID
 INNER JOIN sys.schemas sc
 ON ta.schema_id = sc.schema_id
 WHERE ta.is_ms_shipped = 0 
 AND pa.index_id IN (1,0)
 AND sc.name = @schemaName
 GROUP BY sc.name,ta.name
 ORDER BY sc.name,ta.name

Select 
    tp2.*,tp3.RowCnt 
Into #Detail
From 
    #Temp2 tp2 
    inner join #Temp3 tp3 on tp2.[Schema]=tp3.[Schema] and tp2.[TableName]=tp3.[TableName]

Select
    det.*,
    n.[NullValues]
From
    #Nulls n
    Inner Join #Detail det on det.SchemaTableColumn=n.col
Order By
    det.[Database],
    det.[Schema],
    det.TableName,
    det.[ORDINAL_POSITION]


Drop Table #Nulls
Drop Table #Detail
Drop Table #Temp1
Drop Table #Temp2
Drop Table #Temp3
于 2013-03-05T18:14:00.650 に答える