actionscript-3 - ボタンへのイベント リスナーの追加

Question

私は Actionscript を初めて使用し、プレイヤーが画面下部の 1 から 9 までの数字をクリックして足し算の問題を解決する簡単な足し算ゲームを作成しています。下部に個々のボタンまたはムービークリップを作成する必要がありますか?

ボタン/ムービークリップにイベント リスナーを追加して、プレーヤーが画面上の他のボタンではなく 2 番目のボタンをクリックしたかどうかを確認するにはどうすればよいですか。ありがとうございました！

Answer 1

私がすることは、テキストフィールドを含む単一のムービークリップを作成することです。たとえば、ムービークリップ（リンケージ名はNumClip）と、内部に呼ばれる動的テキストフィールドがありますnumText（数字やその他の必要な文字を必ず埋め込んでください）。次に、単純なforループでうまくいくはずです。

var maxNum:Number = 9;

for (var i:int = 1; i <= maxNum; i++)
{
    var clip:NumClip = new NumClip();
    clip.x = i * (clip.width + 5);
    clip.y = 50;
    clip.id = i;
    clip.numText.text = String(i);
    clip.addEventListener(MouseEvent.CLICK, numClick);
    addChild(clip);
}

function numClick(e:MouseEvent):void
{
    trace("You clicked number " + e.currentTarget.id);
}

私はこのコードをテストしていませんが、私には良さそうなので、トリックを実行する必要があります

Answer 2

Ronnieのソリューションと非常によく似ており（私はこれをほぼ終了したので投稿する必要がありました）、テストされています：

import flash.display.MovieClip;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.events.MouseEvent;
import flash.text.TextFormat;

var buttonCount = 9;
var buttonSize = 50;

var button:MovieClip;
var label:TextField;

for (var i:int = 0; i < buttonCount; i ++)
{
    // Create a new MovieClip
    button = new MovieClip();

    // We'll use this in the event handler to identify which button was clicked
    button.id = i + 1;

    // Draw the background in the graphics prop of the MovieClip
    button.graphics.beginFill(0x00ff00, 1);
    button.graphics.drawRect(0, 0, buttonSize, buttonSize);

    // Add event listener
    button.addEventListener(MouseEvent.CLICK, this.clickHandler);

    // Position the button
    button.x = i * (buttonSize + 20); // Add some spacing
    button.y = stage.stageHeight - buttonSize - 10;

    // Add the button to the stage
    addChild(button);   

    // Create the label for the button
    label = new TextField();
    label.text = button.id.toString();
    label.selectable = false;
    label.multiline = false;
    label.autoSize = TextFieldAutoSize.LEFT;
    label.setTextFormat(new TextFormat('Arial', 12, 0, true));

    // Position the label in the centre of the button
    label.x = (buttonSize - label.width) / 2;
    label.y = (buttonSize - label.height) / 2;

    // Add the label to the button MovieClip
    button.addChild(label);
}

function clickHandler(event:MouseEvent):void
{
    trace("Button clicked:", event.currentTarget.id);
}