1

SQL Server に次のストアド プロシージャがあります。

alter PROCEDURE [dbo].[spSendLogLinesAsXML]
(
    @device_id varchar(128),
    @application_name VARCHAR(64),
    @application_user_name VARCHAR(6),
    @log_lines_xml XML
)
AS
BEGIN

DECLARE
    @ixml INT,
    @log_line_dt DATETIME,
    @log_line_message varchar(max)

EXEC sp_xml_preparedocument @ixml OUTPUT,
    @log_lines_xml

SELECT @log_line_dt = dt,
    @log_line_message = data
FROM OPENXML(@ixml, '/lines/line', 3) WITH (
        dt DATETIME,
        data varchar(max)
        )   

--I want to do the following for each line element      
EXEC spSendLogLine
    @device_id = @device_id,
    @application_name = @application_name,
    @application_user_name = @application_user_name,
    @log_line_dt = @log_line_dt,
    @log_line_message = @log_line_message   

EXEC sp_xml_removedocument @ixml

return -100

END

次のようにストアド プロシージャを呼び出します。

EXEC @return_value = [dbo].[spSendLogLinesAsXML]
     @device_id = N'devid123',
     @application_name = N'CJA App 1',
     @application_user_name = N'anatoli',
     @log_lines_xml = '<lines><line><dt>2013-03-01T13:00:00</dt><data>Something happened and it was logged</data></line><line><dt>2013-03-01T13:01:00</dt><data>Oh my god the building is burning and people are dying</data></line></lines>'

行要素ごとに spSendLogLine を呼び出すようにストアド プロシージャを変更するにはどうすればよいですか?

編集：SQLによると、各レコードカーソルのストアドプロシージャの呼び出しは悪いです。だから、もっといい方法を知りたい。これを達成するためにストアド プロシージャがどれだけ変更されても、それが適切に機能し、適切に機能する限り、気にしません。

4

3 に答える 3

1 
alter PROCEDURE [dbo].[spSendLogLinesAsXML]
(
    @device_id varchar(128),
    @application_name VARCHAR(64),
    @application_user_name VARCHAR(6),
    @log_lines_xml XML
)
AS
BEGIN

declare @log_line_dt datetime,
        @log_line_message varchar(1024)

declare @curse cursor 
set @curse = cursor fast_forward for 
select n.d.value('dt[1]', 'datetime') as log_line_dt, n.d.value('data[1]', 'varchar(1024)') as log_line_message
from @log_lines_xml.nodes('/lines/line') n(d)

open @curse

fetch next from @curse into @log_line_dt, @log_line_message

while (@@fetch_status = 0)
begin
    EXEC spSendLogLine
        @device_id = @device_id,
        @application_name = @application_name,
        @application_user_name = @application_user_name,
        @log_line_dt = @log_line_dt,
        @log_line_message = @log_line_message   

    fetch next from @curse into @log_line_dt, @log_line_message
end

close @curse;

return -100
END
GO
于 2013-03-01T16:41:23.853 に答える
0

If you're using SQL Server 2008 or newer, you could do something like this:

  1. define a user-defined table type that holds all the columns that are relevant to your procedure:

    CREATE TYPE dbo.SendLogLineType 
     AS TABLE (LineDate DATETIME2(3), LineData VARCHAR(200), DeviceID VARCHAR(128), 
               ApplicationName VARCHAR(64), AppUserName VARCHAR(6) )

  2. then, extract your lines into that table, and add the other "fixed" parameters (this happens inside your [spSendLogLinesAsXML] procedure):

    DECLARE @InputTable dbo.SendLogLineType

INSERT INTO @InputTable(LineDate, LineData, DeviceID, ApplicationName, AppUserName)
   SELECT
      XLine.value('(dt)[1]', 'DATETIME2'),
      XLine.value('(data)[1]', 'varchar(200)'), 
      @device_id,
      @application_name,
      @application_user_name
   FROM     
      @log_lines_xml.nodes('/lines/line') AS XTbl(XLine)

  3. and lastly, change your spSendLogLine procedure to accept a table valued parameter of that defined table type and change its logic so that it will iterate over all rows that get passed into it:

    CREATE PROCEDURE spSendLogLine
    (@SendLogLineData dbo.SendLogLineType READONLY)
AS
BEGIN
    -- iterate over all rows in @SendLogLineData and send out those e-mails!
END

Read more about Table-Valued Parameters on the relevant MSDN SQL Server Books Online documentation page

于 2013-03-01T17:17:26.787 に答える
0

これは、muhmudの答えに従って、私が最終的に得たものです。誰かがカーソルなしでそれを行う方法を教えてくれたらいいのにと思います。

ALTER PROCEDURE [dbo].[spSendLogLinesAsXML] 
(
    @device_id VARCHAR(128),
    @application_name VARCHAR(64),
    @application_user_name VARCHAR(6),
    @log_lines_xml XML
)
AS
BEGIN
DECLARE @ixml INT,
    @log_line_dt DATETIME,
    @log_line_message VARCHAR(max),
    @cursor CURSOR

SET @cursor = CURSOR FAST_FORWARD
FOR

SELECT n.d.value('dt[1]', 'datetime') AS log_line_dt,
    n.d.value('data[1]', 'varchar(max)') AS log_line_message
FROM @log_lines_xml.nodes('/lines/line') n(d)

OPEN @cursor

FETCH NEXT
FROM @cursor
INTO @log_line_dt,
    @log_line_message

WHILE (@@fetch_status = 0)
BEGIN
    EXEC spSendLogLine @device_id = @device_id,
        @application_name = @application_name,
        @application_user_name = @application_user_name,
        @log_line_dt = @log_line_dt,
        @log_line_message = @log_line_message

    FETCH NEXT
    FROM @cursor
    INTO @log_line_dt,
        @log_line_message
END

RETURN - 100
END
于 2013-03-01T17:07:59.217 に答える