0

私はこのようなものを書きたいのですが（うまくいきません）：

(defn new-connection []
  (let [c (atom 0)]
    {:id #(swap! c inc)
    :writebuf (ByteBuffer/allocate 8096)
    :readbuf (ByteBuffer/allocate 8096)}))

(new-connection) を使用して段階的に id 化されたマップを取得できるように、カウンターを個別に定義する必要がありますか、またはこの関数でインライン化する方法はありますか?

4

2 に答える 2

2

これは、カウンターを持つ非常に一般的な問題です。物事を少し分解すると、次の 3 つのものが必要であることがわかります。 1) 新しいカウンターを作成するためのもの 2) 接続カウンター 3) この関数を作成するカウンター自体を呼び出すのではなく、id をパラメーターとして受け入れる新しい接続関数より一般的です。

(defn new-counter []
  (partial apply swap! (atom 0) inc []))

(def connection-counter (new-counter))

(defn new-connection [id]
    {:id id
    :writebuf (ByteBuffer/allocate 8096)
    :readbuf (ByteBuffer/allocate 8096)})

これで、次のように使用できます。

(new-connection (connection-counter))
于 2013-03-02T05:19:39.927 に答える
1

closureカウンターを「インライン化」するメカニズムを使用できます。

(let [c (atom 0)]
  (defn new-connection []
    {:id (swap! c inc)
     :writebuf :ByteBuffer
     :readbuf :ByteBuffer})
  (defn get-counter []
    @c))

(get-counter)
=> 0

(new-connection)
=> {:id 1, :writebuf :ByteBuffer, :readbuf :ByteBuffer}

(new-connection)
=> {:id 2, :writebuf :ByteBuffer, :readbuf :ByteBuffer}

(get-counter)
=> 2

または、カウンターの開始値を制御する必要がある場合:

(defn create-connection-fn [init-counter-value]
  (let [c (atom init-counter-value)]
    (fn []
      {:id (swap! c inc)
       :writebuf :ByteBuffer
       :readbuf :ByteBuffer})))

(def new-connection (create-connection-fn 10))

(new-connection)
=> {:id 11, :writebuf :ByteBuffer, :readbuf :ByteBuffer}

(new-connection)
=> {:id 12, :writebuf :ByteBuffer, :readbuf :ByteBuffer}

編集。カウンタを「非表示」にする理由がない場合は、カウンタを分離変数として定義することをお勧めします。

于 2013-03-02T01:38:14.863 に答える