1

質問で申し訳ありませんが、私はプログラミングの初心者であり、おそらくこれは何をすべきかを知っている人にとっては非常に簡単です:

txt ファイルに、増分番号を持つ一連のリンクを作成する必要があります。たとえば、特定の部分を「固定」したままにして、部分を変更する必要があります。たとえば、次のように想像してください。

http://user:password@website.com/members/sets/001/somethingfixed-001.zip テキスト内の次の行は次のようになります。

http://user:password@website.com/members/sets/002/somethingfixed-002.zip など.

指定できる場所を生成し、リンクを作成してすべての行で固定部分を等しく保ち、必要なポイントまで001、002、003を段階的に配置する方法が必要だと思います。

最初のリンクは何か、修正する部分は何か、何を変更する必要があるかを尋ねる .bat ファイルを作成できたら素晴らしいことです。

私はこのようなプログラムを行います：

最初のリンクを挿入し、貼り付けます。

次に、固定部分は何かを尋ねられ、次のように入力します： .../members/sets/X/somethingfixed-Y.zip

変数 X と Y の範囲は? 開始番号？001 を入力すると、終了番号は何ですか? と聞かれます。150 を入力すると、txt ファイルにリンクが生成され、使用できるようになります。

それが明確であることを願っています。

乾杯

4

2 に答える 2

1

例

これは最初の数のためXにそれをします、私はあなたが開発して学ぶためにそれのいくつかを残します。:)

@echo off
setlocal EnableExtensions EnableDelayedExpansion
echo LeftXRight Gen
set /p "Left=Left = "
set /p "Right=Right = "
set /p "Start=Begin = "
set /p "End=End = "
>output.txt ( <nul set /p "=" )
for /L %%A in (%Start%, 1, %End%) do (
    set "X=00%%A"
    echo !Left!!X:~-3!!Right!>>output.txt
)
endlocal

出力

LeftXRight Gen
Left = http://user:password@website.com/members/sets/
Right = /somethingfixed.zip
Start = 1
End = 10

output.txt

http://user:password@website.com/members/sets/001/somethingfixed.zip
http://user:password@website.com/members/sets/002/somethingfixed.zip
http://user:password@website.com/members/sets/003/somethingfixed.zip
http://user:password@website.com/members/sets/004/somethingfixed.zip
http://user:password@website.com/members/sets/005/somethingfixed.zip
http://user:password@website.com/members/sets/006/somethingfixed.zip
http://user:password@website.com/members/sets/007/somethingfixed.zip
http://user:password@website.com/members/sets/008/somethingfixed.zip
http://user:password@website.com/members/sets/009/somethingfixed.zip
http://user:password@website.com/members/sets/010/somethingfixed.zip

アップデート

この完全な解決策を質問に追加しました。

@echo off
setlocal EnableExtensions EnableDelayedExpansion
echo LeftXMidXRight Gen
set /p "Left=Left = "
set /p "Middle=Middle = "
set /p "Right=Right = "
set /p "Start=Begin = "
set /p "End=End = "
>output.txt ( <nul set /p "=" )
for /L %%A in (%Start%, 1, %End%) do (
    set "X=00%%A"
    echo !Left!!X:~-3!!Middle!!X:~-3!!Right!>>output.txt
)
endlocal

例

LeftXMidXRight Gen
Left = http://user:password@website.com/members/sets/
Middle = /somethingfixed-
Right = .zip
Begin = 1
End = 150

output.txt

http://user:password@website.com/members/sets/001/somethingfixed-001.zip
http://user:password@website.com/members/sets/002/somethingfixed-002.zip
...
http://user:password@website.com/members/sets/150/somethingfixed-150.zip
于 2013-03-04T22:31:07.417 に答える
0

これは、いくつかの制限がありますが、あなたが求めているものに近づきます。

URLの末尾にのみ追加できます。

1桁と2桁の数字の接頭辞はゼロではありません。

@echo off

set /p url="Enter URL: "
set /p start="Start Number: "
set /p end="End Number: "

for /L %%X in (%start%, 1, %end% ) do echo %url% %%X >> file.txt
于 2013-03-04T22:30:43.687 に答える