actionscript-3 - mx:List Actionscript 3.0 でアイテムを一覧表示する合計時間を計算する

Question

リストのデータ プロバイダーを更新するときに、リスト項目の合計時間を取得したいと考えています。つまり、データプロバイダーを変更すると、両方の新しいアイテムをロードするのに何ミリ秒かかりますか.
例: データ プロバイダーに 3 つの項目があり、リストへの読み込みに 2 ミリ秒かかります。50 個のアイテムをプッシュすると、15 ミリ秒になる可能性があります。mx.events.ListEvent
を確認しましたが、適切な解決策が見つかりませんでした。ご意見をお待ちしております。

Answer 1

独自のクラスを作成して mx:List を拡張します。以下を参照してください。

package classes
{
    import flash.utils.getTimer;

    import mx.controls.List;

    public class ListCustom extends List
    {

        private var _time:Number;

        public function ListCustom()
        {
            super();
        }

        override public function set dataProvider(value:Object):void
        {
            _time = getTimer();

            super.dataProvider = value;
        }

        override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
        {
            super.updateDisplayList(unscaledWidth, unscaledHeight);

            if (!isNaN(_time))
            {
                var delay:Number = getTimer() - _time;

                _time = NaN;

                trace("delay", delay);
            }
        }
    }
}