43

メソッドをクロージャでラップせずにGroovyのパラメータとして渡す方法はありますか? 関数では機能するようですが、メソッドでは機能しません。たとえば、次の場合:

def foo(Closure c) {
    c(arg1: "baz", arg2:"qux")
}

def bar(Map args) {
    println('arg1: ' + args['arg1'])
    println('arg2: ' + args['arg2'])
}

これは機能します：

foo(bar)

しかしbar、クラス内のメソッドの場合:

class Quux { 
    def foo(Closure c) {
        c(arg1: "baz", arg2:"qux")
    }

    def bar(Map args) {
        println('arg1: ' + args['arg1'])
        println('arg2: ' + args['arg2'])
    }

    def quuux() { 
      foo(bar)
    }
} 

new Quux().quuux()

No such property: bar for class: Quuxで失敗します。

メソッドをクロージャーでラップするように変更するbarと機能しますが、不必要に冗長に見えます。

    def quuux() { 
      foo({ args -> bar(args) })
    }

よりクリーンな方法はありますか？

4

1 に答える 1

69

.&オペレーターが救助に！

class Quux { 
    def foo(Closure c) {
        c(arg1: "baz", arg2:"qux")
    }

    def bar(Map args) {
        println('arg1: ' + args['arg1'])
        println('arg2: ' + args['arg2'])
    }

    def quuux() { 
      foo(this.&bar)
    }
} 

new Quux().quuux()
// arg1: baz
// arg2: qux

一般に、バインドされたメソッド、つまりonobj.&methodを呼び出すクロージャーを返します。methodobj

于 2013-03-05T19:23:25.137 に答える