1

古いバージョンのflexsdkで作成およびコンパイルされたアプリケーションがあります。ここで、このアプリケーションをモバイルデバイスで実行するように移植する必要があるため、sdkをairsdk3.5に変更しました。暗号化/復号化にhurlantライブラリを使用しています。16進クラスのbuには、エラーをスローする行があります。

    if (hex.length&1==1) hex="0"+hex;

（hex.length＆1 == 1）の意味がわかりません。では、どのようにラインを変更する必要がありますか、またはその問題に対する他の解決策はありますか？

4

3 に答える 3

4

私もそのエラーを見ました。FlashBuilder4.7の新しいASC2.0コンパイラでコンパイルすると発生します。

私はに変わり if (hex.length&1==1) hex="0"+hex; ました

 if ((hex.length&1)==1) hex="0"+hex;

そしてそれはそれを修正しました。

于 2013-03-11T21:12:25.843 に答える
0

フレックスとエアの両方が必要になります！
私にはタイプミスのように見えます。

if (hex.length==1) hex="0"+hex;

ifステートメントが何を探すべきかによって異なります

私の悪い編集
私はその演算子について知りませんでした、私はモジュラスでそれをしたでしょう！
私はあなたの優れたスキルに屈します。

于 2013-03-11T11:47:31.887 に答える
0

if(hex.length&1==1)これは、hex.lengthが奇数（1,3,5,7 ...）であるかどうかをチェックすることを意味します。

次のように参照してください。

var str:String = "111";

if(str.length&1==1)
{
   str = "0" + str;

   trace(str);
}

構文は問題ありません。きっと。どのようなエラーが表示されますか？

私は持っていHex.asます。ただし、構文エラーは発生しません。Flash Builder 4.6では、FlashCS6AIR3.5。

package com.hurlant.util
{
    import flash.utils.ByteArray;

    public class Hex
    {
        /**
         * Support straight hex, or colon-laced hex.
         * (that means 23:03:0e:f0, but *NOT* 23:3:e:f0)
         * Whitespace characters are ignored.
         */
        public static function toArray(hex:String):ByteArray {
            hex = hex.replace(/\s|:/gm,'');
            var a:ByteArray = new ByteArray;
            if (hex.length&1==1) hex="0"+hex;
            for (var i:uint=0;i<hex.length;i+=2) {
                a[i/2] = parseInt(hex.substr(i,2),16);
            }
            return a;
        }

        public static function fromArray(array:ByteArray, colons:Boolean=false):String {
            var s:String = "";
            for (var i:uint=0;i<array.length;i++) {
                s+=("0"+array[i].toString(16)).substr(-2,2);
                if (colons) {
                    if (i<array.length-1) s+=":";
                }
            }
            return s;
        }

        /**
         * 
         * @param hex
         * @return a UTF-8 string decoded from hex
         * 
         */
        public static function toString(hex:String):String {
            var a:ByteArray = toArray(hex);
            return a.readUTFBytes(a.length);
        }


        /**
         * 
         * @param str
         * @return a hex string encoded from the UTF-8 string str
         * 
         */
        public static function fromString(str:String, colons:Boolean=false):String {
            var a:ByteArray = new ByteArray;
            a.writeUTFBytes(str);
            return fromArray(a, colons);
        }

    }
}
于 2013-03-11T12:24:11.480 に答える