2

これが私の最初の質問です。

XSL 1.0 を使用してこの xml を変換したい:

<RESULTS>
    <RES>
      <GROUP>1</GROUP>
      <SUBGROUP>A</SUBGROUP>
      <NAME>Alice</NAME>
    </RES>

    <RES>
      <GROUP>1</GROUP>
      <SUBGROUP>A</SUBGROUP>
      <NAME>Bart</NAME>
    </RES>

    <RES>
      <GROUP>1</GROUP>
      <SUBGROUP>B</SUBGROUP>
      <NAME>Keira</NAME>
    </RES>

    <RES>
      <GROUP>2</GROUP>
      <SUBGROUP>A</SUBGROUP>
      <NAME>Mike</NAME>
    </RES>

    <RES>
      <GROUP>2</GROUP>
      <SUBGROUP>B</SUBGROUP>
      <NAME>Peter</NAME>
    </RES>

    <RES>
      <GROUP>2</GROUP>
      <SUBGROUP>B</SUBGROUP>
      <NAME>Olaf</NAME>
    </RES>

</RESULTS>

これに：

    <h1> 1 </h1>
       <h2>A</h2>
         <p>Alice</p>
         <p>Bart</p>

       <h2>B</h2>
         <p>Keira</p>

    <h1> 2 </h1>
       <h2>A</h2>
         <p>Mike</p>

       <h2>B</h2>
         <p>Peter</p>
         <p>Olaf</p>

Muenchian Method を使用してみましたが、これでは GROUP でのみ並べ替えることができ、並べ替えた結果を SUBGROUP で並べ替えることができませんでした。グループ/サブグループごとに 1 回だけヘッダーを表示する必要があることに注意してください。

@ CMスペルバーグ・マックイーン

テキストの壁を投稿したくありませんでしたが、それが役立つ場合は、次のようにします。

これは私が試した解決策の1つです：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="byGROUP" match="RESULTS/RES" use="GROUP" />
    <xsl:template match="RESULTS">
        <xsl:for-each select="RES[count(. | key('byGROUP', GROUP)[1]) = 1]">
            <xsl:sort select="GROUP" order="descending" />
            <h1>
                <xsl:value-of select="GROUP" />
            </h1>

            <xsl:for-each select="key('byGROUP', GROUP)">
                <xsl:sort select="SUBGROUP" order="descending" />
                <h2>
                    <xsl:value-of select="SUBGROUP" />
                </h2>

                <p>
                    <xsl:value-of select="NAME" />
                </p>

            </xsl:for-each>

        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

preceiding-sibling を使用して SUBGROUP を表示するかどうかをテストしようとしましたが、ノードを反復処理することは不可能であることがわかったため、おそらく適切なアプローチではありません。

4

1 に答える 1

2

複数のグループ化を行う一般的な方法は、現在のレベルの値とすべての親の値をキー値として連結して使用することです。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes" omit-xml-declaration="yes"/>
  <xsl:key name="byGROUP" match="RESULTS/RES" use="GROUP" />
  <xsl:key name="bySUBGROUP" match="RESULTS/RES"
           use="concat(GROUP, '+', SUBGROUP)" />  

  <xsl:template match="RESULTS">
    <xsl:apply-templates
      select="RES[count(. | key('byGROUP', GROUP)[1]) = 1]
                 /GROUP">
      <xsl:sort select="." order="ascending" />
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="GROUP">
    <h1>
      <xsl:value-of select="." />
    </h1>
    <xsl:variable name="thisGroup" select="key('byGROUP', .)" />
    <xsl:apply-templates
      select="$thisGroup[count(. | 
                          key('bySUBGROUP', concat(GROUP, '+', SUBGROUP))[1])
                         = 1]
                        /SUBGROUP">
      <xsl:sort select="." order="ascending" />
    </xsl:apply-templates>
  </xsl:template>

  <xsl:template match="SUBGROUP">
    <h2>
      <xsl:value-of select="." />
    </h2>
    <xsl:apply-templates select="key('bySUBGROUP', concat(../GROUP, '+', .))"/>
  </xsl:template>

  <xsl:template match="RES">
    <p>
      <xsl:value-of select="NAME" />
    </p>
  </xsl:template>
</xsl:stylesheet>

サンプル入力で実行すると、次が生成されます。

<h1>1</h1>
<h2>A</h2>
<p>Alice</p>
<p>Bart</p>
<h2>B</h2>
<p>Keira</p>
<h1>2</h1>
<h2>A</h2>
<p>Mike</p>
<h2>B</h2>
<p>Peter</p>
<p>Olaf</p>
于 2013-03-11T18:25:55.360 に答える