10

計算シェーダーを介して OpenGL でレイトレーシングを実行しようとしていますが、奇妙な問題に遭遇しました。現時点では、シェーディングなしで球を表示したいだけです。私の計算シェーダーは、すべてのピクセルに対してレイを起動し、次のようになります。

#version 430
struct Sphere{
    vec4    position;
    float   radius;
};

struct Ray{
    vec3    origin;
    vec3    dir;
};

uniform image2D outputTexture;
uniform uint        width;
uniform uint        height;

float hitSphere(Ray r, Sphere s){

    float s_vv = dot(r.dir, r.dir);
    float s_ov = dot(r.origin, r.dir);
    float s_mv = dot(s.position.xyz, r.dir);
    float s_mm = dot(s.position.xyz, s.position.xyz);
    float s_mo = dot(s.position.xyz, r.origin);
    float s_oo = dot(r.origin, r.origin);

    float d = s_ov*s_ov-2*s_ov*s_mv+s_mv*s_mv-s_vv*(s_mm-2*s_mo*s_oo-s.radius*s.radius);

    if(d < 0){
        return -1.0f;
    } else if(d == 0){
        return (s_mv-s_ov)/s_vv;
    } else {
        float t1 = 0, t2 = 0;
        t1 = s_mv-s_ov;

        t2 = (t1-sqrt(d))/s_vv;
        t1 = (t1+sqrt(d))/s_vv;

        return t1>t2? t2 : t1 ; 
    }
}

layout (local_size_x = 16, local_size_y = 16, local_size_z = 1) in;
void main(){
    uint x = gl_GlobalInvocationID.x;
    uint y = gl_GlobalInvocationID.y;

    if(x < 1024 && y < 768){
        float t = 0.0f;
        Ray r = {vec3(0,0,0), vec3(width/2-x, height/2-y, 1000)};
        Sphere sp ={vec4(0, 0, 35, 1), 5.0f};

        t = hitSphere(r, sp);

        if(t <= -0.001f){
            imageStore(outputTexture, ivec2(x, y), vec4(0.0, 0.0, 0.0, 1.0));
        } else {
            imageStore(outputTexture, ivec2(x, y), vec4(0.0, 1.0, 0.0, 1.0));
        }

        if(x == 550 && y == 390){
            imageStore(outputTexture, ivec2(x, y), vec4(1.0, 0.0, 0.0, 1.0));
        }
    } 
}

アプリケーションを実行すると、次の画像が表示されます。 ここに画像の説明を入力

しかし、CPU で同じアルゴリズムを実行すると、次のより説得力のあるイメージが得られます。 ここに画像の説明を入力

最初に、すべてのピクセルが独自の計算シェーダー呼び出しを取得しないように、十分なワークグループをディスパッチしなかったと考えましたが、そうではありません。GPU でレンダリングされたイメージでわかるように、コンピューティング シェーダーの最後の行が原因で、中央に赤いピクセルがあります。これは、1 ピクセルおきに再現できます。

現時点では 1024x768 の解像度を使用しており、計算シェーダーをディスパッチする方法は次のとおりです。

#define WORK_GROUP_SIZE 16
void OpenGLRaytracer::renderScene(int width, int height){
    glUseProgram(_progID);

    glDispatchCompute(width/WORK_GROUP_SIZE, height/WORK_GROUP_SIZE,1);

    glMemoryBarrier(GL_TEXTURE_FETCH_BARRIER_BIT);
}

間違いはどこですか？浮動小数点計算の精度に問題があるのでしょうか?

4

1 に答える 1

5

間違いは次の行にあります。

Ray r = {vec3(0,0,0), vec3(width/2-x, height/2-y, 1000)};

幅、高さ、x および y は符号なし変数であるため、幅/2-x という項が負になると問題が発生します。

これは問題を解決します：

Ray r = {vec3(0,0,0), vec3(float(width)/2.0f-float(x), float(height)/2.0f-float(y), 1000)};
于 2013-03-15T10:01:53.087 に答える