1 
[a]                   [b]                   [c]
Chrome            Chrome            Chrome
Chrome            Internet Explorer Chrome
Chrome            Chrome            Chrome
Firefox           Firefox           Chrome
Internet Explorer Chrome            Chrome
Safari            Safari            Chrome

SPSSは初めてなので、これが基本的なものであれば申し訳ありません。aからbまでの各オプションの頻度の変化のグラフ表現（折れ線グラフ）を作成しようとしています。そして、a、b、c。

変数ごとに、各オプションの％を計算し、それをプロットする必要があると思います。

どんな助けでも大歓迎です。

4

1 に答える 1

0

私が望むものを生成するための簡単な答えは、データをワイドからロングに再形成してから、要約チャートを作成することです。以下の例：

*Making fake data that looks like yours.
input program.
loop #i = 1 to 1000.
    compute caseid = #i.
    compute A = TRUNC(RV.UNIFORM(1,4)).
    compute B = TRUNC(RV.UNIFORM(1,4)).
    compute C = TRUNC(RV.UNIFORM(1,4)).
    end case.
end loop.
end file.
end input program.
dataset name Sim.
value labels A B C
1 'Chrome'
2 'Firefox'
3 'IE'.

*Reshape Wide to long.
VARSTOCASES
/MAKE Browser from A B C
/INDEX Period.

*Now make the summary chart.
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=Period COUNT()[name="COUNT"] Browser
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
 SOURCE: s=userSource(id("graphdataset"))
 DATA: Period=col(source(s), name("Period"), unit.category())
 DATA: COUNT=col(source(s), name("COUNT"))
 DATA: Browser=col(source(s), name("Browser"), unit.category())
 GUIDE: axis(dim(1), label("Period"))
 GUIDE: axis(dim(2), label("Count"))
 GUIDE: legend(aesthetic(aesthetic.color.interior), label("Browser"))
 SCALE: cat(dim(1))
 SCALE: linear(dim(2))
 SCALE: cat(aesthetic(aesthetic.color.interior), include("1.00", "2.00","3.00"))
 ELEMENT: line(position(Period*COUNT), color.interior(Browser), missing.wings())
END GPL.

このチャートを作成します：

ここに画像の説明を入力してください

測定データを繰り返した場合（つまり、同じ人が複数の期間にわたってブラウザを使用した場合）、グラフ化できるデータの構造が増えます。1つの方法初期状態を条件とした面グラフを検討できます。以下は例です。事後編集を行うと、チャートはこれを生成します。

ここに画像の説明を入力してください

do if Period = 1.
    compute initial_browser = Browser.
else if Period > 1.
    compute initial_browser = lag(Browser).
end if.
value labels initial_browser
1 'Chrome'
2 'Firefox'
3 'IE'.

GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=Period COUNT()[name=
  "COUNT"] initial_browser Browser
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
 SOURCE: s=userSource(id("graphdataset"))
 DATA: Period=col(source(s), name("Period"), unit.category())
 DATA: COUNT=col(source(s), name("COUNT"))
 DATA: initial_browser=col(source(s), name("initial_browser"),unit.category())
 DATA: Browser=col(source(s), name("Browser"), unit.category())
 GUIDE: axis(dim(1), label("Period"))
 GUIDE: axis(dim(2), label("Count"))
 GUIDE: axis(dim(4), label("Initial Browser"), opposite())
 GUIDE: legend(aesthetic(aesthetic.color.interior), label("Browser"))
 SCALE: cat(dim(1))
 SCALE: linear(dim(2), include(0))
 SCALE: cat(dim(4))
 SCALE: cat(aesthetic(aesthetic.color.interior), include("1.00", "2.00",
  "3.00"))
 ELEMENT: area.stack(position(Period*COUNT*1*initial_browser),
  color.interior(Browser), missing.wings())
END GPL.

これが事実である場合、他の多くのチャート作成の可能性があります。

于 2013-03-12T13:21:16.337 に答える