5

Groovyは、指定されたすべてのパラメーターをマップに収集し、それを最初のパラメーターとしてメソッドに渡します。これはきれいに見えますが、それを機能させようとした後、それは本当に使用できないようです。

したがって、問題は次のような方法です。

def method(paramMap, specificVar1 = 7, specificVar2 = 14)

このメソッドを次のように呼び出すと、次のようになります。

method(12, extraValue: "hello")

あなたはあなたが期待するものをほとんど手に入れます：

assert 12 == specificVar1
assert 14 == specificVar2
assert [extraValue:"hello"] == paramMap

悪くない、理にかなっている。Map問題は、パラメータがオプションであると仮定すると、次のような値になる可能性があることです。

method(12)

assert paramMap == 12
assert specificVar1 == 7 // default values
assert specificVar2 == 14

そのスカラーは、マップではなく、specificVarに配置されている必要があります。メソッドにマップを具体的に入力すると、次のようになります。

def method(Map paramMap, specificVar1 = 7, specificVar2 = 14)

その後method(12, extraValue: "hello")、以前と同じように機能しますが、method(12)をスローしClassCastExceptionます。これは使用できないようです。パラメータMapがない場合に単に空になるように、その「スティッキー」を作成する方法はありますか？Map

4

1 に答える 1

14

パラメータにデフォルト値を設定すると、左から右への組み合わせでオーバーロードされたメソッドが作成されるため、作成が難しく、method(12)マップ エントリを渡すこともできません。

メソッドdef method(paramMap, specificVar1=7, specificVar2=14)は次のメソッドを生成します。

Object Maps.method(java.lang.Object)
Object Maps.method(java.lang.Object,java.lang.Object)
Object Maps.method(java.lang.Object,java.lang.Object,java.lang.Object)

そして、map パラメータを持つ完全に型指定されたメソッド:

def method3(Map paramMap=[:], Integer specificVar1=7, Integer specificVar2=14) {
}

次のメソッドを生成します。

Object Maps.method3()
Object Maps.method3(java.util.Map)
Object Maps.method3(java.util.Map,java.lang.Integer)
Object Maps.method3(java.util.Map,java.lang.Integer,java.lang.Integer)

( に適した方法はありませんmethod(12))。

また、メソッドに渡されたエントリが収集され、最初のマップパラメータに挿入されます。次の方法:

def method4(Integer specificVar1=7, Integer specificVar2=14, Map map=[:]) {

生成:

Object Maps.method4()
Object Maps.method4(java.lang.Integer)
Object Maps.method4(java.lang.Integer,java.lang.Integer)
Object Maps.method4(java.lang.Integer,java.lang.Integer,java.util.Map)

したがって、次のようにmethod4 12, a:'b'失敗します。

No signature of method: Maps.method4() is applicable for argument types: 
  (java.util.LinkedHashMap, java.lang.Integer) values: [[a:b], 12]

だから、いいえ、マップを使ってやりたいことができるとは思いません:-)。

解決策 1:

純粋な動的ソリューションが必要な場合は、単一のマップ引数を使用できます。

def method5(Map map) {
  def specificVar1 = map.specificVar1 ?: 7
  def specificVar2 = map.specificVar2 ?: 14
}

解決策 2 (更新):

パラメータを表すクラスを作成できます。マップをオブジェクトに強制的に使用することは、静的にコンパイル可能であり、そのためのシンタティック シュガーです。

@groovy.transform.CompileStatic
class Maps {
  def method6(Foo foo) { "$foo.params, $foo.specificVar1, $foo.specificVar2" }
  def method6(Map map) { method6 map as Foo }

  static main(args) {
    def maps = new Maps()

    assert maps.method6(params: [a: 'b', c: 'd'], specificVar1: 40) ==
        "[a:b, c:d], 40, 14"

    assert maps.method6(new Foo(params: [a: 'b', c: 'd'], specificVar2: 21)) == 
        "[a:b, c:d], 7, 21"
  }
}

class Foo {
  def specificVar1 = 7, specificVar2 = 14, params = [:]
}

解決策 3:

オーバーロードされたメソッド。

def method6(Map paramMap, Integer specificVar1=7, Integer specificVar2=14) {
  "$paramMap, $specificVar1, $specificVar2"
}

def method6(Integer specificVar1=7, Integer specificVar2=14) {
  method6 [:], specificVar1, specificVar2
}


assert method6( 12 ) == "[:], 12, 14"
assert method6( ) == "[:], 7, 14"
assert method6( a:'b', 18 ) == "[a:b], 18, 14"
assert method6( 18, a:'b', 27 ) == "[a:b], 18, 27"
assert method6( 90, 100 ) == "[:], 90, 100"
assert method6( a:'b', 140, c:'d' ) == "[a:b, c:d], 140, 14"

マップ バージョン メソッドにデフォルト パラメータを指定することはできません。そうしないと、両方のメソッドがパラメータなしを生成し、method6競合が発生します。

于 2013-03-13T20:01:17.317 に答える