batch-file - バッチを使用して外部バッチ構成値を編集する

Question

次の内容を含む config.conf という名前の構成ファイルがあります。

[Config]
password=1234 
usertries=0 
allowterminate=0 

usertries の値を 5 に編集したいのですが、それを行うのに役立つバッチ スクリプト コードはありますか?

ありがとう

Answer 1

これは少し面倒ですが、うまくいくはずです：

@echo off
set ConfigFile=config.conf
setlocal enabledelayedexpansion
(for /f "delims=" %%L in (%ConfigFile%) do (
  set "LINE=%%L"
  if "!LINE:~0,10!"=="usertries=" (echo usertries=5) else (echo !LINE!)
)) > %ConfigFile%.new
move /y %ConfigFile%.new %ConfigFile% > nul

で始まる場合を除き、基本的には各行を新しいファイルに書き込みますusertries=。その場合、置換行を挿入するだけです。その後、新しいファイルを古いファイルの上に移動して置き換えます。

Answer 2

@ECHO OFF
setlocal
::
:: set %1 to value %2 in config.conf
::
SET target=%2&IF NOT DEFINED target ECHO syntax is %0 keyname newvalue&GOTO :EOF 
SET target=Config.conf
MOVE /y %target% %target%.old >NUL
FOR /f "tokens=1*delims==" %%i IN (%target%.old) DO (
IF /i %%i==%1 (ECHO %%i=%2) ELSE (
IF "%%j"=="" (ECHO %%i) ELSE (ECHO %%i=%%j)
)
) >>%target%

このバージョンでは、既存のキーを値に変更できます。

thisbatchname existingkey newvalue

Answer 3

私はパーティーに少し遅れていることを知っていますが、この質問に対処するために、汎用の ini ファイル ユーティリティ バッチ スクリプトを作成することにしました。

このスクリプトを使用すると、ini スタイル ファイルの値を取得または変更できます。その検索では大文字と小文字が区別されず、ini ファイルに空白行が保持されます。本質的に、それは一種の非常に初歩的なデータベースとして ini ファイルと対話することを可能にします。

:: --------------------
:: ini.bat
:: ini.bat /? for usage
:: --------------------

@echo off
setlocal enabledelayedexpansion

goto begin

:usage
echo Usage: %~nx0 /i item [/v value] [/s section] inifile
echo;
echo Take the following ini file for example:
echo;
echo    [Config]
echo    password=1234
echo    usertries=0
echo    allowterminate=0
echo;
echo To read the "password" value:
echo    %~nx0 /s Config /i password inifile
echo;
echo To change the "usertries" value to 5:
echo    %~nx0 /s Config /i usertries /v 5 inifile
echo;
echo In the above examples, "/s Config" is optional, but will allow the selection of
echo a specific item where the ini file contains similar items in multiple sections.
goto :EOF

:begin
if "%~1"=="" goto usage
for %%I in (item value section found) do set %%I=
for %%I in (%*) do (
    if defined next (
        if !next!==/i set item=%%I
        if !next!==/v set value=%%I
        if !next!==/s set section=%%I
        set next=
    ) else (
        for %%x in (/i /v /s) do if "%%~I"=="%%x" set "next=%%~I"
        if not defined next (
            set "arg=%%~I"
            if "!arg:~0,1!"=="/" (
                1>&2 echo Error: Unrecognized option "%%~I"
                1>&2 echo;
                1>&2 call :usage
                exit /b 1
            ) else set "inifile=%%~I"
        )
    )
)
for %%I in (item inifile) do if not defined %%I goto usage
if not exist "%inifile%" (
    1>&2 echo Error: %inifile% not found.
    exit /b 1
)

if not defined section (
    if not defined value (
        for /f "usebackq tokens=2 delims==" %%I in (`findstr /i "^%item%\=" "%inifile%"`) do (
            echo(%%I
        )
    ) else (
        for /f "usebackq delims=" %%I in (`findstr /n "^" "%inifile%"`) do (
            set "line=%%I" && set "line=!line:*:=!"
            echo(!line! | findstr /i "^%item%\=" >NUL && (
                1>>"%inifile%.1" echo(%item%=%value%
                echo(%value%
            ) || 1>>"%inifile%.1" echo(!line!
        )
    )
) else (
    for /f "usebackq delims=" %%I in (`findstr /n "^" "%inifile%"`) do (
        set "line=%%I" && set "line=!line:*:=!"
        if defined found (
            if defined value (
                echo(!line! | findstr /i "^%item%\=" >NUL && (
                    1>>"%inifile%.1" echo(%item%=%value%
                    echo(%value%
                    set found=
                ) || 1>>"%inifile%.1" echo(!line!
            ) else echo(!line! | findstr /i "^%item%\=" >NUL && (
                for /f "tokens=2 delims==" %%x in ("!line!") do (
                    echo(%%x
                    exit /b 0
                )
            )
        ) else (
            if defined value (1>>"%inifile%.1" echo(!line!)
            echo(!line! | find /i "[%section%]" >NUL && set found=1
        )
    )
)

if exist "%inifile%.1" move /y "%inifile%.1" "%inifile%">NUL

例：

C:\Users\me\Desktop>type config.conf
[Config]
password=1234
usertries=0
allowterminate=0

[Other]
password=foo

C:\Users\me\Desktop>ini /i usertries /v 5 config.conf
5

C:\Users\me\Desktop>ini /i usertries config.conf
5

C:\Users\me\Desktop>ini /s config /i password /v bar config.conf
bar

C:\Users\me\Desktop>ini /s other /i password /v baz config.conf
baz

C:\Users\me\Desktop>type config.conf
[Config]
password=bar
usertries=5
allowterminate=0

[Other]
password=baz