0

キーを使用したミュンチアン法を使用してグループ化するアイテムのセットがあります。これはうまく機能しています。私の問題は、グループ化後にレコードの数を取得し、メッセージヘッダーの数を使用する方法です。 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="groups" match="RECORD" use="VALUE"/>
   <xsl:template match="Test">
   <Header>
      <NoOfRecords>
         <HOW TO GET THE NO OF RECORDS= HERE?/>
      </NoOfRecords>
    </Header>
    <Message>
       <xsl:for-each select="RECORD[generate-id(.)=generate-id(key('groups',VALUE))]">
          <Value>
             <xsl:value-of select="VALUE/text()" />
          </Value>
       </xsl:for-each>
    </Message>
  </xsl:template>
</xsl:stylesheet>
4

1 に答える 1

0

これはそれを行う必要があります：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>
  <xsl:key name="groups" match="RECORD" use="VALUE"/>
  <xsl:template match="Test">
    <xsl:variable name="distinctItems"
                  select="RECORD[generate-id()=generate-id(key('groups',VALUE)[1])]" />
    <Header>
      <NoOfRecords>
        <xsl:value-of select="count($distinctItems)"/>
      </NoOfRecords>
    </Header>
    <Message>
      <xsl:for-each select="$distinctItems">
        <Value>
          <xsl:value-of select="VALUE/text()" />
        </Value>
      </xsl:for-each>
    </Message>
  </xsl:template>
</xsl:stylesheet>

もちろん、これを2つのテンプレートに分けることをお勧めします。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>
  <xsl:key name="groups" match="RECORD" use="VALUE"/>
  <xsl:template match="Test">
    <xsl:variable name="distinctItems"
                  select="RECORD[generate-id()=generate-id(key('groups',VALUE)[1])]" />
    <Header>
      <NoOfRecords>
        <xsl:value-of select="count($distinctItems)"/>
      </NoOfRecords>
    </Header>
    <Message>
      <xsl:apply-templates select="$distinctItems" />
    </Message>
  </xsl:template>

  <xsl:template match="RECORD">
    <Value>
      <xsl:value-of select="VALUE/text()" />
    </Value>
  </xsl:template>
</xsl:stylesheet>
于 2013-03-14T13:03:54.987 に答える