2

次のパッケージがスローされます: PLS-00386: FETCH カーソルと INTO 変数の間の 'V_STUDYTBL' でタイプの不一致が見つかりました

コードの目的: パッケージの外部で 2 つの型を定義します。1 つは一連の数値をストアド プロシージャに送信するために使用され、もう 1 つは my_table から対応する行を返すために使用されます。

入力していただきありがとうございます。

Create OR REPLACE Type InputTyp  AS VARRAY(200) OF VARCHAR2 (1000);

CREATE  TYPE OBJTYP AS OBJECT
   (
    A            NUMBER,
    B             VARCHAR2 (1000),       
    C        VARCHAR2 (100)       
 );
CREATE TYPE OutputTyp IS VARRAY (2000) OF   OBJTYP;
/

CREATE OR REPLACE PACKAGE my_package
AS
   PROCEDURE my_procedure(p_StudyNum   IN     InputTyp,
                                     p_StdyDtl        OutputTyp);
END my_package;
/
CREATE OR REPLACE PACKAGE BODY my_package
AS
   PROCEDURE MyProcedure(p_StudyNum   IN     InputTyp,
        p_StdyDtl        OutputTyp)
IS
  i            BINARY_INTEGER := 1;
  j            BINARY_INTEGER := 1;
  CURSOR c_StudyTbl
  IS
     SELECT A,  B, C
       FROM my_table
      WHERE Study_Number = p_StudyNum(i);

  v_StudyTbl   OBJTYP;
BEGIN
  p_StdyDtl := OutputTyp ();
  LOOP
     --  This is the first cursor opened for each of the items in the list.
      EXIT WHEN i > p_StudyNum.count;

     OPEN c_StudyTbl;
     LOOP

        FETCH c_StudyTbl INTO v_StudyTbl;
        EXIT WHEN c_StudyTbl%NOTFOUND;

        p_StdyDtl.EXTEND ();
        p_StdyDtl (j).A := v_StudyTbl.A;
        p_StdyDtl (j).B := v_StudyTbl.B;
        p_StdyDtl (j).C := v_StudyTbl.C;
        j := j + 1;
     END LOOP;
     CLOSE c_StudyTbl;
    i := i + 1;
  END LOOP;

  IF c_StudyTbl%ISOPEN
  THEN
     CLOSE c_StudyTbl;
  END IF;
EXCEPTION
  WHEN NO_DATA_FOUND
  THEN
     NULL;
END;
END my_package;
/
4

2 に答える 2

3

select でオブジェクト コンストラクターを使用する必要があります。

SELECT OBJTYP(A, B, C)
   FROM my_table
  WHERE Study_Number = p_StudyNum(i)

ただし、これらすべてのループの代わりに、手順をこれに単純化できます。

begin
select cast(multiset(select /*+ cardinality(s, 10) */ a, b, c
                        from my_table t, table(p_StudyNum) s
                      where t.study_number = s.column_value) as OutputTyp)
   into p_StdyDtl
   from dual;
end;
于 2013-03-19T15:45:38.657 に答える
1

カーソルを次のように宣言してみてください。 

CURSOR c_StudyTbl
IS
  SELECT OBJTYP(A, B, C)
    FROM my_table
    WHERE Study_Number = p_StudyNum(i);
于 2013-03-19T15:38:04.000 に答える