2

以下の関数からmsbuildを呼び出し、出力を新しいバッファーにリダイレクトしたいと思います。

私の問題は、ファイル名に変数を使用する必要があるため、「！」を使用できないことです。（私はできますか？）そして、exeまたはsystem（）を使用すると、readは適切なファイルを提供していないと文句を言います。

func! myFunction()
    let findstr = "findstr /s /m " . '"' . expand("%:t") . '"' . " *.vcxproj"
    for project in split(system(findstr), nr2char(10))
        echo "Building '" . project . "'"
        let msbuild = "c:\\windows\\Microsoft.NET\\Framework\\v4.0.30319\\msbuild.exe" . " " . project . " " . "/t:rebuild /p:configuration=debug"
        :tabnew | r system(msbuild) "<--THIS LINE HERE
    endfor
endfunc
4

2 に答える 2

2

この:readコマンドは、vim式ではなくファイルを取ります。ただし、を介して標準出力から読み込むことができます:read !{cmd}。例:%r!ls。このコマンドを使用する:executeと、変数を使用して新しいコマンドを作成できます。

exe '%r!' . msbuild

または:put、のような式を使用する場合は、式レジスタと一緒に使用できますsystem()。（おそらくこれに続い:0d_て最初の空の行を削除したい）

put=system(msbuild)

これで、プロジェクトをビルドしてエラーのリストを取得しようとしているように見えます。これはプロジェクトを構築するためのよりvimな方法であるため、、オプション、およびリスト:makeを'makeprg'調べることをお勧めします。quickfix

詳細については、以下を参照してください。

:h :r!
:h :exe
:h :pu
:h @=
:h :make
:h 'makeprg'
:h quickfix
于 2013-03-19T18:16:13.037 に答える
0

これは、任意のシェルコマンドを実行し、それらの出力を新しいウィンドウに表示するために使用できる関数です（これを_vimrcに入れることができます）。

let s:lastcmd = ''
function! s:RunShellCommand(cmdline, bang)
    " Support for repeating last cmd with bang:
    let _ = a:bang != '' ? s:lastcmd : a:cmdline == '' ? '' : join(map(split(a:cmdline), 'expand(v:val)'))

    if _ == ''
        return
    endif

    let s:lastcmd = _
    let bufnr = bufnr('%')
    let winnr = bufwinnr(_)
    " You can position the new window whenever you want, I chose below + right:
    silent! execute  winnr < 0 ? 'belowright new ' . fnameescape(_) : winnr . 'wincmd w'
    " I could set buftype=nofile, but then no switching back and forth buffers.
    " The results are presented just for viewing, not editing, modify at will:
    setlocal buftype=nowrite bufhidden=wipe nobuflisted noswapfile wrap number

    setlocal modifiable
    silent! :%d
    " Useful for debugging, if you encounter issues with fnameescape():
    call setline(1, 'You entered:  ' . a:cmdline)
    call setline(2, 'Expanded to:  ' . _)
    call append(line('$'), substitute(getline(2), '.', '=', 'g'))

    silent execute '$read !' . _
    silent! execute 'autocmd BufUnload <buffer> execute bufwinnr(' . bufnr . ') . ''wincmd w'''
    " If resizing is unwanted for commands with too much output, remove this line:
    silent! execute 'autocmd BufEnter  <buffer> execute ''resize '' .  line(''$'')'
    " You can use <localleader>r to re-execute the last command:
    silent! execute 'nnoremap <silent> <buffer> <localleader>r :call <SID>RunShellCommand(''' . _ . ''', '''')<CR>'

    execute 'resize ' . line('$')

    setlocal nomodifiable
    1
endfunction " RunShellCommand(cmdline)
command! -complete=shellcmd -nargs=* -bang Shell call s:RunShellCommand(<q-args>, '<bang>')

次のように使用します：

:Shell gcc -ggdb -o test test.c && ./test
于 2013-03-19T19:43:26.773 に答える