20

ファイルを1行ずつ読み取るには、次のものがあります。

wscript.echo "BEGIN"

filePath = WScript.Arguments(0)
filePath = "C:\Temp\vblist.txt"
Set ObjFso = CreateObject("Scripting.FileSystemObject")
Set ObjFile = ObjFso.OpenTextFile(filePath)
StrData = ObjFile.ReadLine
wscript.echo "END OF FIRST PART"

Do Until StrData = EOF(ObjFile.ReadLine)
    wscript.echo StrData
    StrData = ObjFile.ReadLine
Loop

wscript.echo "END"

EOF()関数が機能していないようです：

C:\Users\EGr\Documents\Scripts\VB>cscript testloop.vbs ArgVal
Microsoft (R) Windows Script Host Version 5.8
Copyright (C) Microsoft Corporation. All rights reserved.

BEGIN
END OF FIRST PART
C:\Users\EGr\Documents\Scripts\VB\testloop.vbs(11, 1) Microsoft VBScript runti
me error: Type mismatch: 'EOF'

これまでVBでプログラミングしたことはありませんが、渡されたVBスクリプトを変更できるように、ループを理解しようとしています。ファイルを1行ずつ読み取り、各行で何かを実行したいと思います。DoUntilループをに変更するとDo Until StrData = EOF、機能しますが、ファイルの最後に到達するとエラーがスローされます。

C:\Users\EGr\Documents\Scripts\VB>cscript testloop.vbs ThisRANDOMValue
Microsoft (R) Windows Script Host Version 5.8
Copyright (C) Microsoft Corporation. All rights reserved.

BEGIN
1
END OF FIRST PART
host1
host2
host3
C:\Users\EGr\Documents\Scripts\VB\testloop.vbs(13, 2) Microsoft VBScript runti
me error: Input past end of file

おそらく簡単な解決策があるように感じますが、私はそれを見つけることができませんでした。私はオンラインで見つけた他のいくつかの解決策を試しましたが、上記ほど近づいていません。

4

2 に答える 2

42

疑わしい場合は、ドキュメントをお読みください。

filename = "C:\Temp\vblist.txt"

Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile(filename)

Do Until f.AtEndOfStream
  WScript.Echo f.ReadLine
Loop

f.Close
于 2013-03-20T19:49:58.703 に答える
3

私のような人が特定の行だけを読み取るために検索している場合、ここでの例は18行目だけです。

filename = "C:\log.log"

Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.OpenTextFile(filename)

For i = 1 to 17
    f.ReadLine
Next

strLine = f.ReadLine
Wscript.Echo strLine

f.Close
于 2014-11-24T10:05:59.693 に答える