4

大きなデータセットを集約して次のようなものを取得したい

SELECT SUM(`profit`) as `profit`, `month` FROM `t` GROUP BY `month`

だから、私はそのようにclojureのgroup-by関数を修正しました

(defn group-reduce [f red coll]
  (persistent!
   (reduce
    (fn [ret x]
      (let [k (f x)]
        (assoc! ret k (red (get ret k) x))))
    (transient {}) coll)))

そして、ここに使用法があります：

(group-reduce :month (fn [s x]
                       (if s
                         (assoc s :profit (+ (:profit s) (:profit x)))
                         x))
              [{:month 10 :profit 12}
               {:month 10 :profit 15}
               {:month 12 :profit 1}])

#_=> {10 {:profit 27, :month 10}, 12 {:profit 1, :month 12}}

動作しますが、clojure 標準ライブラリを使用してこれを行う別の方法があるのでしょうか?

4

2 に答える 2

5

コアに最も近いのはmerge-with：

(def t [{:month 10 :profit 12}
        {:month 10 :profit 15}
        {:month 12 :profit 1}])

(apply merge-with + (for [x t] {(:month x) (:profit x)}))
;=> {12 1, 10 27}
于 2013-03-23T21:26:01.423 に答える
2

いくつかの例：

user=> (def groups (group-by :month [{:month 10 :profit 12}
  #_=>                               {:month 10 :profit 15}
  #_=>                               {:month 12 :profit 1}])
{10 [{:profit 12, :month 10} {:profit 15, :month 10}], 12 [{:profit 1, :month 12}]}

user=> (for [[k v] groups] {:month k :sum-profit (apply + (map :profit v))})
({:month 10, :sum-profit 27} {:month 12, :sum-profit 1})

user=> (into {} (for [[k v] groups] [k (apply + (map :profit v))]))
{10 27, 12 1}
于 2013-03-22T11:44:38.657 に答える