0

1993 年の EITC 制度の改革前後で、「子供が 1 人いるシングルマザー」と「子供が 1 人以上いるシングルマザー」の 2 つのグループの平均を比較しようとしています。

SPSS の手順 T 検定で、改革前後のグループの違いを得ることができます。しかし、どうすれば差の差を得ることができますか (それでも標準誤差が必要です)?

私はSTATAとRのためのこれらの方法を見つけました（http://thetarzan.wordpress.com/2011/06/20/differences-in-differences-estimation-in-r-and-stata/）が、私はできないようですSPSSでそれを理解してください。

誰かが助けてくれることを願っています。

ごきげんよう、アン

4

3 に答える 3

0

一般線形モデル、私はそれを「ANOVA」モデルとみなします。

そのため、SPSS の Analyze メニューにある関連モジュールを使用してください。

T 検定の後、各グループのシグマの等価性を確認する必要があります。

于 2013-09-02T09:45:41.950 に答える
0

これは、GENLIN プロシージャーで実行できます。方法を示すために生成したランダム データを次に示します。

data list list /after oneChild value.
begin data.
0   1   12
0   1   12
0   1   11
0   1   13
0   1   11
1   1   10
1   1   9
1   1   8
1   1   9
1   1   7
0   0   16
0   0   16
0   0   18
0   0   15
0   0   17
1   0   6
1   0   6
1   0   5
1   0   5
1   0   4
end data.
dataset name exampleData WINDOW=front.
EXECUTE.

value labels after 0 'before' 1 'after'.
value labels oneChild 0 '>1 child' 1 '1 child'.

グループの平均 (順番に、整数に切り捨てる前) は、それぞれ 17、6、12、および 9 です。したがって、GENLIN プロシージャーは、-11 (>1 子グループの前後差)、-5 (1 子 - >1 子の差)、および 8 (前後差の子差) の値を生成する必要があります。 ）。

データをグラフ化して、私たちが期待していることを確認できるようにします。

* Chart Builder.
GGRAPH
  /GRAPHDATASET NAME="graphdataset" VARIABLES=after value oneChild MISSING=LISTWISE REPORTMISSING=NO    
  /GRAPHSPEC SOURCE=INLINE.
BEGIN GPL
  SOURCE: s=userSource(id("graphdataset"))
  DATA: after=col(source(s), name("after"), unit.category())
  DATA: value=col(source(s), name("value"))
  DATA: oneChild=col(source(s), name("oneChild"), unit.category())
  GUIDE: axis(dim(2), label("value"))
  GUIDE: legend(aesthetic(aesthetic.color.interior), label(""))
  SCALE: linear(dim(2), include(0))
  ELEMENT: line(position(smooth.linear(after*value)), color.interior(oneChild))
  ELEMENT: point.dodge.symmetric(position(after*value), color.interior(oneChild))
END GPL.

さて、ゲンリンについて：

* Generalized Linear Models.
GENLIN value BY after oneChild (ORDER=DESCENDING)
  /MODEL after oneChild after*oneChild INTERCEPT=YES
 DISTRIBUTION=NORMAL LINK=IDENTITY
  /CRITERIA SCALE=MLE COVB=MODEL PCONVERGE=1E-006(ABSOLUTE) SINGULAR=1E-012 ANALYSISTYPE=3(WALD) 
    CILEVEL=95 CITYPE=WALD LIKELIHOOD=FULL
  /MISSING CLASSMISSING=EXCLUDE
  /PRINT CPS DESCRIPTIVES MODELINFO FIT SUMMARY SOLUTION.

結果の表は、私たちが期待するものを示しています。

  • >1 の子グループは、前に比べて後が 12.3 ～ 10.1 低くなります。この 95% CI には、「実際の」値である 11 が含まれています。

  • >1 人の子供と 1 人の子供の前の差は 5.7 - 3.5 で、実際の値は 5 です。

  • 差の差は 9.6 - 6.4 で、(17-6) - (12-9) = 8 の実際の値が含まれます。

標準 エラー、p 値、およびその他の仮説検定の値もすべて報告されます。それが役立つことを願っています。

編集:これは、相互作用項を自分で計算し、単純な線形回帰を行うことにより、「複雑な」構文で実行できます。

compute interaction = after*onechild.
execute.

REGRESSION
  /MISSING LISTWISE
  /STATISTICS COEFF OUTS CI(95) R ANOVA
  /CRITERIA=PIN(.05) POUT(.10)
  /NOORIGIN 
  /DEPENDENT value
  /METHOD=ENTER after oneChild interaction.

結果として得られる標準誤差と信頼区間は、実際には前の方法とは異なることに注意してください。SPSS の GENLIN および REGRESSION 手順について、その理由を説明するのに十分な知識はありません。この不自然な例では、データから引き出す結論はほぼ同じです。実生活では、データがこれほどクリーンである可能性は低いため、どの方法が「より良い」かはわかりません。

于 2013-05-08T17:36:18.263 に答える
0

上記の最初の回答について：

* Note that GENLIN uses maximum likelihood estimation (MLE) whereas REGRESSION
* uses ordinary least squares (OLS).  Therefore, GENLIN reports z- and Chi-square tests
* where REGRESSION reports t- and F-tests.  Rather than using GENLIN, use UNIANOVA
* to get the same results as REGRESSION, but without the need to compute your own
* product term.

UNIANOVA value BY after oneChild
  /PLOT=PROFILE(after*oneChild) 
  /PLOT=PROFILE(oneChild*after) 
  /PRINT PARAMETER
  /EMMEANS=TABLES(after*oneChild) COMPARE(after)
  /EMMEANS=TABLES(after*oneChild) COMPARE(oneChild)
  /DESIGN=after oneChild after*oneChild.

HTH。

于 2018-06-20T13:11:44.430 に答える