0

PP リンクの精度を確認するためのテスト ビデオを作成しました。誰かがテキストをクリックすると、ビデオは開始ブックマークから終了ブックマークまで再生されます。ブックマークの最後で止まるとは限りません！なぜ？パワーポイントのパフォーマンスの問題？

画像を載せたいのですが、少なくとも10の評判が必要なのでできません。

更新: アクション設定を使用しています。

トリガー付きコード

Private Sub setStartAndEndPointOnVideoTrigger(activeSlide As Slide, clickShape As Shape, movieShape As Shape, _
                          startBookmark As MediaBookmark, endBookmark As MediaBookmark)

   Dim oEffectStart As Effect
   Dim oEffectEnd As Effect
   Dim obhvEffect As AnimationBehavior
   Dim delayTime As Double

   delayTime = (endBookmark.Position - startBookmark.Position) / 1000

   With activeSlide
   Set oEffectStart = .TimeLine.InteractiveSequences.Add _
                        .AddTriggerEffect(movieShape, msoAnimEffectMediaPlayFromBookmark, _
                        msoAnimTriggerOnShapeClick, clickShape, startBookmark.Name)

   Set oEffectEnd = .TimeLine.InteractiveSequences.Add _
                        .AddTriggerEffect(movieShape, msoAnimEffectMediaPause, _
                        msoAnimTriggerOnShapeClick, clickShape)

   Set obhvEffect = oEffectStart.Behaviors.Add(msoAnimTypeCommand)
   obhvEffect.CommandEffect.Bookmark = startBookmark.Name

   oEffectEnd.Timing.TriggerType = msoAnimTriggerWithPrevious
   oEffectEnd.Timing.TriggerDelayTime = delayTime
   End With

   End Sub
4

1 に答える 1

0

私は 2010 バージョンの新しいメソッドのいくつかに慣れていないため、追加の問題がある可能性がありますが、With ステートメントの使用に関していくつかの問題があるようです。これを試して：

Private Sub setStartAndEndPointOnVideoTrigger(activeSlide As Slide, clickShape As Shape, movieShape As Shape, _
                          startBookmark As MediaBookmark, endBookmark As MediaBookmark)

    Dim oEffectStart As Effect
    Dim oEffectEnd As Effect
    Dim obhvEffect As AnimationBehavior
    Dim delayTime As Double

    delayTime = (endBookmark.Position - startBookmark.Position) / 1000

    With activeSlide.TimeLine.InteractiveSequences

        With .Add(1)
            Set oEffectStart = .AddTriggerEffect(movieShape, msoAnimEffectMediaPlayFromBookmark, _
                                msoAnimTriggerOnShapeClick, clickShape, startBookmark.Name)
        End With

        With .Add(2)
            Set oEffectEnd = .AddTriggerEffect(movieShape, msoAnimEffectMediaPause, _
                            msoAnimTriggerOnShapeClick, clickShape)
        End With

    End With

    Set obhvEffect = oEffectStart.Behaviors.Add(msoAnimTypeCommand)
    obhvEffect.CommandEffect.Bookmark = startBookmark.Name

    oEffectEnd.Timing.TriggerType = msoAnimTriggerWithPrevious
    oEffectEnd.Timing.TriggerDelayTime = delayTime

End Sub
于 2013-03-26T17:43:57.077 に答える