data-structures - Clojure マップのロールアップ

Question

私は似たようなデータ構造を持っています

[{:Gender "Boy" :Cat1 "Foo" :Cat2 "Bar" :SKU 111}
 {:Gender "Boy"  :Cat1 "Foo" :Cat2 "Bar" :SKU 222}
 {:Gender "Girl" :Cat1 "Foo" :Cat2 "Bar" :SKU 333}
 {:Gender "Boy" :Cat1 "Foo" :Cat2 "Woo" :SKU 444}]

次のようなデータ構造を構築したい

   [{:Name "Boy" 
      :Children
       { :Name "Foo"
         :Children
          {:Name "Bar"
           :Children
             {:SKU 111}
             {:SKU 222}
          }
          {:Name "Woo"
           :Children
             {:SKU 444}
          }
      }
    {:Name "Girl"
      :Children
       {:Name "Foo"
        :Children
         {:Name "Bar"
          :Children
            {:SKU 333}
         }
        }            
       }]          

私はClojureにかなり慣れていないので、答えが明らかな場合はすみません。

Answer 1

正確にはあなたが望むものではありませんが、近いかもしれません:

user=> (def foo  [{:Gender "Boy" :Cat1 "Foo" :Cat2 "Bar" :SKU 111}
  #_=>      {:Gender "Boy"  :Cat1 "Foo" :Cat2 "Bar" :SKU 222}
  #_=>      {:Gender "Girl" :Cat1 "Foo" :Cat2 "Bar" :SKU 333}
  #_=>      {:Gender "Boy" :Cat1 "Foo" :Cat2 "Woo" :SKU 444}])
#'user/foo

user=> (group-by (juxt :Gender :Cat1 :Cat2) foo)
    {["Boy" "Foo" "Bar"] [{:Gender "Boy", :Cat2 "Bar", :Cat1 "Foo", :SKU 111} 
     {:Gender "Boy", :Cat2 "Bar", :Cat1 "Foo", :SKU 222}], 
     ["Girl" "Foo" "Bar"] [{:Gender "Girl", :Cat2 "Bar", :Cat1 "Foo", :SKU 333}], 
     ["Boy" "Foo" "Woo"] [{:Gender "Boy", :Cat2 "Woo", :Cat1 "Foo", :SKU 444}]}

user=> (def foo2 (group-by (juxt :Gender :Cat1 :Cat2) foo))
#'user/foo2

user=>  (zipmap (keys foo2) (map #(map :SKU %) (vals foo2)))
{["Boy" "Foo" "Woo"] (444), ["Girl" "Foo" "Bar"] (333), ["Boy" "Foo" "Bar"] (111 222)}

Answer 2

以下は解決策です（注：:Childrenマップのリストである必要があります）

(def data [{:Gender "Boy" :Cat1 "Foo" :Cat2 "Bar" :SKU 111}
           {:Gender "Boy"  :Cat1 "Foo" :Cat2 "Bar" :SKU 222}
           {:Gender "Girl" :Cat1 "Foo" :Cat2 "Bar" :SKU 333}
           {:Gender "Boy" :Cat1 "Foo" :Cat2 "Woo" :SKU 444}])


(defn gp-by [data key]
  (->> (group-by key data)
       (map (fn [[k v]] {:Name k
                        :Children (map #(dissoc % key) v)}))))


(map (fn [m] (assoc m :Children
                   (map (fn [n] (assoc n :Children (gp-by (n :Children) :Cat2)))
                        (gp-by (m :Children) :Cat1)))) (gp-by data :Gender))