0

私のサンプル xml は以下のようになります: xml から個別の状態を取得する必要があります。vs 2010 エディターで xslt 1.0 を使用しています。

<?xml version="1.0" encoding="utf-8" ?>
<states>
  <node>
    <value>2</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>NJ</state>
  </node>
  <node>
    <value>1</value>
    <state>NY</state>
  </node>

  <node>
    <value>1</value>
    <state>NY</state>
  </node>
</states>

私のxsltは以下のようになります：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
   xmlns:user="urn:my-scripts">

  <xsl:output method="text" indent="yes"/>

  <xsl:key name="st" match="//states/node/state" use="." />

  <xsl:variable name="disst">
    <xsl:for-each select="//states/node[contains(value,1)]/state[generate-id()=generate-id(key('st',.)[1])]" >
      <xsl:choose>
        <xsl:when test="(position() != 1)">
          <xsl:value-of select="concat(', ',.)" disable-output-escaping="yes"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="." disable-output-escaping="yes"/>
        </xsl:otherwise>
      </xsl:choose>

    </xsl:for-each>


  </xsl:variable>

    <xsl:template match="/" >
      <xsl:value-of disable-output-escaping="yes" select="$disst"/>

    </xsl:template>
</xsl:stylesheet>

出力: ドイツ、ニュージャージー、ニューヨーク

上記の xml は、上記のテスト xml に適しています。

以下のようにxmlを変更すると：

<?xml version="1.0" encoding="utf-8" ?>
<states>
  <node>
    <value>2</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>NJ</state>
  </node>
  <node>
    <value>1</value>
    <state>NY</state>
  </node>

  <node>
    <value>1</value>
    <state>NY</state>
  </node>
</states>

状態 DE を選択しないことにあります。誰でも適切な解決策を提案できますか。事前に感謝します。xml から個別の状態を見つける必要があります。

4

1 に答える 1

2

ここでの問題は、Muenchian グループ化 XPath での述語の使用です。

[contains(value,1)]

これにより、多くの場合、Muenchian のグループ化で、使用可能な個別の値をすべて見つけることができなくなります。代わりに、述語をキーに追加する必要があります。

<xsl:key name="st" match="//states/node[contains(value, 1)]/state" use="." />

または、グループ化ステートメント内で述語を適用できます。

<xsl:apply-templates 
   select="//states/node
               /state[generate-id() =
                      generate-id(key('st',.)[contains(../value, 1)][1])]" />

完全な XSLT (一部改善あり):

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:user="urn:my-scripts">
  <xsl:output method="text" indent="yes"/>

  <xsl:key name="st" match="//states/node/state" use="." />
  <xsl:variable name="a" select="1" />

  <xsl:variable name="disst">
    <xsl:apply-templates
       select="//states/node
                   /state[generate-id() =
                          generate-id(key('st',.)[contains(../value, $a)][1])]" />
  </xsl:variable>

  <xsl:template match="state">
    <xsl:if test="position() > 1">
      <xsl:text>,</xsl:text>
    </xsl:if>
    <xsl:value-of select ="." disable-output-escaping="yes" />
  </xsl:template>

  <xsl:template match="/" >
    <xsl:value-of disable-output-escaping="yes" select="$disst"/>

  </xsl:template>
</xsl:stylesheet>

サンプル XML で実行した結果:

DE,NJ,NY
于 2013-04-04T19:35:11.953 に答える