1

私は perl でオブジェクトに苦労しており、2 次元配列を作成してオブジェクトのハッシュ フィールドに格納しようとしています。2次元配列を作成するには、配列への参照の配列が必要であることを理解していますが、それを実行しようとすると、次Type of arg 1 to push must be array (not hash element)のエラーが発生します。コンストラクターは正常に動作し、正常にset_seqs動作しますが、create_matrixサブがこれらのエラーをスローしています。

これが私がやっていることです：

sub new {
    my ($class) = @_;
    my $self = {};
    $self->{seq1} = undef;
    $self->{seq2} = undef;
    $self->{matrix} = ();
    bless($self, $class);
    return $self;
}
sub set_seqs {
    my $self = shift;
    $self->{seq1} = shift;
    $self->{seq2} = shift;
    print $self->{seq1};
}

sub create_matrix {
    my $self = shift;
    $self->set_seqs(shift, shift);
    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [lengthofseq1][lengthofseq2]
    for (my $i = 0; $i < length($self->{seq1}) - 1; $i++) {
        #push a new array reference onto the matrix
        #this line generates the error
        push(@$self->{matrix}, []);
    }
}

私が間違っていることについて何か考えはありますか？

4

3 に答える 3

4

$self を逆参照するときに、余分な中かっこのセットがありません。試してみてくださいpush @{$self->{matrix}}, []。

疑わしい場合 (複雑なデータ構造で正しい値を参照しているかどうかわからない場合) は、中括弧を追加します。:) perldoc perlreftutを参照してください。

于 2009-10-21T19:07:40.683 に答える
3

Perlは非常に表現力豊かな言語です。以下のステートメントですべてを行うことができます。

$self->{matrix} = [ map { [ (0) x $seq2 ] } 1..$seq1 ];

このゴルフですか？たぶん、しかしそれはまたpush、気難しいプロトタイプをいじくり回すことを避けます。私は以下のステートメントを爆発させます：

$self->{matrix} = [     # we want an array reference
    map {               # create a derivative list from the list you will pass it
        [ (0) x $seq2 ] # another array reference, using the *repeat* operator 
                        # in it's list form, thus creating a list of 0's as 
                        # long as the value given by $seq2, to fill out the  
                        # reference's values.
   } 
   1..$seq1             # we're not using the indexes as anything more than  
                        # control, so, use them base-1.
];                       # a completed array of arrays.

テーブルを作成するための標準のサブルーチンがあります。

sub make_matrix { 
    my ( $dim1, $dim2 ) = @_;
    my @table = map { [ ( 0 ) x $dim2 ] } 1..$dim1;
    return wantarray? @table : \@table;
}

そして、これがより一般化された配列配列関数です：

sub multidimensional_array { 
    my $dim = shift;
    return [ ( 0 ) x $dim ] unless @_; # edge case

    my @table = map { scalar multidimensional_array( @_ ) } 1..$dim;
    return wantarray ? @table : \@table;
}
于 2009-10-21T19:54:48.523 に答える
2 
sub create_matrix {
    my($self,$seq1,$seq2) = @_;
    $self->set_seqs($seq2, $seq2);

    #create the 2d array of scores
    #to create a matrix:
    #create a 2d array of length [$seq1][$seq2]
    for( 1..$seq1 ){
        push @{$self->{matrix}}, [ (undef) x $seq2 ];
    }
}
于 2009-10-21T19:11:37.707 に答える