2

AQ$_MESSAGES_EXCEPTIONまず、次の質問があることを知っています: Oracle AQ でキューをクリアする方法ですが、答えがありません。

Oracle AQ の例外キューに大量のメッセージ (500k) があります (期限切れのメッセージが別のキューに移動されることを知らなかったので、それらのコンシューマーを作成しませんでした)。私が今必要としているのは、それらのメッセージをすばやく削除できるようにすることです。一貫性のない状態につながる可能性があるため、delete を使用してキュー テーブルをクリアすることはお勧めできません。以下の手順でまとめてみましたが、毎秒50通程度しかクリアできません

EXECUTE dbms_aqadm.start_queue(queue_name => 'AQ$_MESSAGES_EXCEPTION', 
                               enqueue => FALSE, dequeue => TRUE);

DECLARE
   dequeue_options     DBMS_AQ.dequeue_options_t;
   message_properties  DBMS_AQ.message_properties_t;
   message_handle      RAW(16);
   message             SYS.AQ$_JMS_MESSAGE;
   no_messages         EXCEPTION;
   pragma exception_init (no_messages, -25228);
BEGIN
   dequeue_options.wait := DBMS_AQ.NO_WAIT;
   dequeue_options.navigation := DBMS_AQ.FIRST_MESSAGE;
   LOOP
   DBMS_AQ.DEQUEUE(
      queue_name          =>     'AQ$_MESSAGES_EXCEPTION',
      dequeue_options     =>     dequeue_options,
      message_properties  =>     message_properties,
      payload             =>     message,
      msgid               =>     message_handle);
  DBMS_OUTPUT.put_line ('Message: ' || message_handle || ' dequeued');
  END LOOP;
  EXCEPTION
    WHEN no_messages THEN
      DBMS_OUTPUT.put_line (' ---- NO MORE MESSAGES  ---- ');
    WHEN others then
      DBMS_OUTPUT.put_line ('Exception queue not started for dequeue.');
END;

/

データベース マシン上で実行されていることを考えると、非常に遅いようです。この手順は、500k メッセージで約 3 時間かかります。もっと効果的な方法でそれを行うことはできますか？

編集：

ここのリンクから dequeue_array を試しました: http://www.oracle-developer.net/display.php?id=319 しかし、テーブルを作成できないため、「格納」する配列を作成しようとしています。結果。これが私が持っているものです：

DECLARE
    type messages_type  is varray(500) of SYS.AQ$_JMS_MESSAGE;
    messages            messages_type;
    dequeue_options     DBMS_AQ.dequeue_options_t;
    msg_properties      DBMS_AQ.message_properties_array_t;
    msg_ids             DBMS_AQ.MSGID_ARRAY_T;
    x_timeout           EXCEPTION;
    no_messages         EXCEPTION;
    dequeue_batch       PLS_INTEGER := 500;
    pragma exception_init (no_messages, -25228);
BEGIN        
    messages := messages_type();
    msg_properties := DBMS_AQ.MESSAGE_PROPERTIES_ARRAY_T();
    msg_properties.EXTEND(dequeue_batch);      
    msg_ids := DBMS_AQ.MSGID_ARRAY_T();   
    dequeue_options.wait := 5;   
LOOP
    DBMS_AQ.DEQUEUE_ARRAY(
    queue_name          =>     'AQ$_MESSAGES_EXCEPTION',
    dequeue_options     =>     dequeue_options,
    array_size          =>     dequeue_batch,
    message_properties_array  =>     msg_properties,
    payload_array             =>     messages,
    msgid_array               =>     msg_ids); 
...

次のエラーが表示されます。

wrong number or types of arguments in call to 'DEQUEUE_ARRAY'

問題はメッセージ配列にあると思いますが、それを機能させるために何をすべきかわかりません。また、オラクルのドキュメント（http://docs.oracle.com/cd/B19306_01/appdev.102/b14258/d_aq.htm#i1000850）によると、別のパラメータがあるはずです：

error_array               OUT  error_array_t

ただし、このパラメーターの説明は「現在実装されていません」です。どういう意味ですか？省略できますか？null に設定する必要がありますか? これは本当に紛らわしく、Googleはここでは役に立ちません:(

4

2 に答える 2

3

本当にデキューしたい場合は、おそらく dequeue_array(n) 関数を使用できます。それははるかに速いはずです。

しかし、あなたが提供するリンクには解決策があります:

-- purge queue
DECLARE
 po_t dbms_aqadm.aq$_purge_options_t;
BEGIN
  dbms_aqadm.purge_queue_table('MY_QUEUE_TABLE', NULL, po_t);
END;

それ以外の場合、この例外キューは自動的に作成されるため、削除するだけでよいと思いますが、それが安全かどうかはわかりません

BEGIN
  DBMS_AQADM.STOP_QUEUE(
     queue_name => 'demo_queue'
     );
  DBMS_AQADM.DROP_QUEUE(
     queue_name => 'demo_queue'
     );
  DBMS_AQADM.DROP_QUEUE_TABLE(
     queue_table => 'demo_queue_table'
     );
END;
于 2013-04-22T07:19:20.047 に答える
2

dbms_aqadm パッケージからプロシージャ「purge_queue_table」(@Stephane が言ったように) を使用できますが、「purge_condition」パラメータを指定すると、このパラメータを使用して、削除するメッセージを選択できます。

例 ：

declare

    purge_options dbms_aqadm.aq$_purge_options_t;

begin

      purge_options.block := false;

      purge_options.delivery_mode := dbms_aqadm.persistent;

      dbms_aqadm.purge_queue_table
         (queue_table     => 'vista.svig_std_tab',
          purge_condition => 'qtview.queue = ''AQ$_SVIG_STD_TAB_E'' and qtview.enq_time < to_date(''01.06.2014 00:00:00'',''dd.mm.yyyy hh24:mi:ss'') ',
          purge_options   => purge_options
         );

end;
/

この例では、指定された例外キューからのもので、指定された日付より古いメッセージを削除します。また、「dbms_aq.dequeue」プロシージャを使用するよりもはるかに迅速にこれを行います。

于 2016-05-10T11:32:14.073 に答える