3

XML ドキュメントを変換しようとしています。まず、グローバル変数を定義しています。

 <xsl:variable name="foo"><xsl:value-of select="bar"/></xsl:variable>

ここで、変換しようとしている XML が<bar>some data</bar>定義されている可能性があります。また、定義されていない可能性もあります。

以下のグローバル変数を宣言したら、定義されている場合は次を出力しようとしています。

<foo>DEFINED</foo>

定義されていない場合:

<foo>NOT DEFINED</foo>

私は使っている<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

これについて最善の方法は何ですか？

4

3 に答える 3

7

XSLT 1.0 を使用string()しているため、テストを実行するために使用できます。

スタイルシートの例を次に示します。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar"/>
        <results>
            <xsl:choose>
                <xsl:when test="string($foo)">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>

空白は折りたたまれているため、<bar> </bar>false が返されることに注意してください。また、string()変数の代わりに要素を直接テストするときにも機能します。

入力/出力の例を次に示します。

入力

<test>
    <bar/>
</test>

また

<test>
    <bar></bar>
</test>

また

<test>
    <bar>    </bar>
</test>

出力

<foo>NOT DEFINED</foo>

入力

<test>
    <bar>x</bar>
</test>

出力

<foo>DEFINED</foo>

XSLT 2.0 を使用できる場合は、変数を として宣言xs:stringし、テストで変数名を使用するだけです ( test="$foo")。

例：

<xsl:stylesheet version="2.0" xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar" as="xs:string"/>
        <results>
            <xsl:choose>
                <xsl:when test="$foo">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>
于 2013-04-16T23:53:11.950 に答える
0

これが機能するかどうかはわかりませんが...

スタイルシートに追加xmlns:fn="http://www.w3.org/2005/xpath-functions"します。

<xsl:choose>
  <xsl:when test="fn:boolean(foo)">
    <foo>DEFINED</foo>
  </xsl:when>
  <xsl:otherwise>
    <foo>NOT DEFINED</foo>
  </xsl:otherwise>
</xsl:choose>

編集: @JimGarrison これは、動作する場合は<bar/>or<bar></bar>を定義どおりに扱います。

于 2013-04-16T22:29:09.530 に答える