18

国と会社の 2 つのワークシートを含む Excel ワークブックがあります。次のように、企業ワークシートは、国ワークシートの を通じて部分的に入力さVLOOKUPれます。

国:

     A       B
1 COUNTRY HOF_LTO
2 Belgium    4
3 Japan      5
4 Spain
5 Sweden     0

企業:

    A         B       C
1 COMPANY  COUNTRY HOF_LTO
2 Belgacom Belgium    4
3 Onkyo    Japan      5
4 Sony     Japan      5
5 ATTM     Spain      0
6 Nokia    Sweden     0

C次の式を使用して列を埋めています。

=VLOOKUP($B2;countries!$A$1:$C$5;MATCH(companies!B$1;countries!$1:$1;0);FALSE)

間違っているのは、国に値SpainがなくてもHOF_LTO、式は0cell に適切な値として配置することですcompanies!C5。代わりに、スウェーデンの場合のように、セルを空のままにして、[countries] タブにある0場合にのみゼロ ( ) を入力する必要があります。0

一致する国の値がない場合にセルが空のままになるように、数式を編集するにはどうすればよいですか?

4

8 に答える 8

45

これで解決するはずです：

=VLOOKUP(...) & ""

これにより、Excel はそのセルを強制的にテキスト値として参照するようになり、空白がゼロに変換されなくなります。

https://superuser.com/a/906954/222835から取得

于 2016-07-30T22:21:08.713 に答える
8 
=CONCATENATE(VLOOKUP($B2;countries!$A$1:$C$5;MATCH(companies!B$1;countries!$1:$1;0);FALSE))

Concatenate は、データが数値ではなく文字列のように扱われることを保証します。値が単なる空のセルの場合、空のセルが得られます。

于 2014-04-30T00:09:25.123 に答える
4

国シートにすべての国が一度しか存在しない場合は、代わりに次を使用できます。

=IF(ISNUMBER(OFFSET(countries!$B$1;MATCH(B2;countries!A:A;0)-1;0));
    OFFSET(countries!$B$1;MATCH(B2;countries!A:A;0)-1;0);
    "")
于 2013-04-20T21:37:01.717 に答える
0

または、制御する必要があるのがデータの表示だけである場合は、セルの書式設定を調整して、0 の値を数字のゼロではなく空白として表示します。

于 2013-04-20T22:13:06.070 に答える