1

TColor の 2 次元配列があります。また、TCanvas もあります。このカラー マップをforサイクルよりも速くキャンバスに描画するにはどうすればよいですか?

例えば：

type
  T2DAr = array of array of TColor;

var
  ar: T2DAr;
  Form1: TForm; // mainform

function main;
var x, y: integer;
begin
{filling array with colors as a 10x10}

for x := 0 to length(ar)-1 do
for y := 0 to length(ar[x])-1 do
Form1.Canvas.Pixels[x, y] := ar[x, y];
end;

この方法では動作が遅すぎます。より高速なアルゴリズムが必要です。

4

1 に答える 1

5

これは何度も答えられています。答えはscanline、非常に遅いPixelsプロパティの代わりに s を使用することです。例：

function CreateBitmapReallyFast: TBitmap;
const
  WHITE: TRGBTriple = (rgbtBlue: 255; rgbtGreen: 255; rgbtRed: 255);
  BLACK: TRGBTriple = (rgbtBlue: 0; rgbtGreen: 0; rgbtRed: 0);
var
  y: Integer;
  scanline: PRGBTriple;
  x: Integer;
begin
  result := TBitmap.Create;
  result.SetSize(1920, 1080);
  result.PixelFormat := pf24bit;
  for y := 0 to result.Height - 1 do
  begin
    scanline := result.ScanLine[y];
    for x := 0 to result.Width - 1 do
    begin
      if odd(x) then
        scanline^ := WHITE
      else
        scanline^ := BLACK;
      inc(scanline);
    end;
  end;
end;

さらにクール：

with scanline^ do
begin
  rgbtBlue := Random(255);
  rgbtGreen := Random(255);
  rgbtRed := Random(255);
end;

それを試すには：

procedure TForm1.FormPaint(Sender: TObject);
var
  bm: TBitmap;
begin
  bm := CreateBitmapReallyFast;
  try
    Canvas.Draw(0, 0, bm);
  finally
    bm.Free;
  end;
end;

もちろん、TRGBTripleまたはの (パックされた) 配列がTRGBQuadあり、ビットマップのピクセル形式が同じであればMove、メモリ内のデータを配列からビットマップのスキャンラインに単純に変換できます。

于 2013-04-25T14:45:10.923 に答える