4

HTTPポストを介してファイルを受信し、それをファイルシステムに保存するPerl CGIスクリプトを作成するにはどうすればよいですか？

4

4 に答える 4

9

CGI モジュールを使用します。

my $fh = $query->upload('upload_field');
while(<$fh>) {
  print SAVE_FILE $_;
}
于 2008-10-02T14:52:25.137 に答える
7

注意点: どのように記述しても、Web サーバーからアクセスできる場所に保存しないでください。

要点: 以下は、写真のアップロードにしばらく使用していたスクリプトです。微調整が必​​要かもしれませんが、道を示してくれるはずです。

画像は Web アクセス可能なディレクトリにアップロードされていないため、画像のチェック、サイズ変更、透かしの挿入、およびアクセス可能な場所への配置を別のプロセスで行います。

 #!/usr/bin/perl -wT

use strict;
use CGI;
use CGI::Carp qw ( fatalsToBrowser );
use File::Basename;

$CGI::POST_MAX = 1024 * 5000;
my $safe_filename_characters = "a-zA-Z0-9_.-";
my $upload_dir = "/home/www/upload";

my $query = new CGI;
my $filename = $query->param("photo");
my $email_address = $query->param("email_address");

if ( !$filename )
{
 print $query->header ( );
 print "There was a problem uploading your photo (try a smaller file).";
 exit;
}

my ( $name, $path, $extension ) = fileparse ( $filename, '\..*' );
$filename = $name . $extension;
$filename =~ tr/ /_/;
$filename =~ s/[^$safe_filename_characters]//g;

if ( $filename =~ /^([$safe_filename_characters]+)$/ )
{
 $filename = $1;
}
else
{
 die "Filename contains invalid characters";
}

my $upload_filehandle = $query->upload("photo");

open ( UPLOADFILE, ">$upload_dir/$filename" ) or die "$!";
binmode UPLOADFILE;

while ( <$upload_filehandle> )
{
 print UPLOADFILE;
}

close UPLOADFILE;

print $query->header ( );
print <<END_HTML;
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "DTD/xhtml1-strict.dtd">
<html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en" lang="en">
 <head>
   <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
   <title>Thanks!</title>
 </head>
 <body>
   <p>Thanks for uploading your photo!</p>
 </body>
</html>
END_HTML
于 2008-10-02T14:49:09.090 に答える
6

ファイルのアップロードについては、CGI.pm のドキュメントを参照してください。

于 2008-10-02T14:50:40.227 に答える
4

まず、 CGIを使用してCREATING A FILE UPLOAD FIELDを読み、openを使用してファイルを作成し、printを使用して書き込みます。（そしてそれを閉じるために閉じます）。

于 2008-10-02T15:12:35.743 に答える