2

作成したオブジェクトを、そのオブジェクトが実装するインターフェイスを必要とする別のオブジェクトのコンストラクターに渡しています。

  ISomeInterface = interface
  ['{840D46BA-B9FB-4273-BF56-AD0BE40AA3F9}']
  end;

  TSomeObject = class(TInterfacedObject, ISomeinterface)
  end;

  TSomeObject2 = class
  private
    FSomeInterface: ISomeinterface;
  public
    constructor Create(SomeObject: ISomeInterface);
  end;

var
Form1: TForm1; // main form
SomeObject: TSomeObject;

constructor TSomeObject2.Create(SomeObject: ISomeInterface);
begin
  FSomeInterface := SomeObject;
end;

// main form creating
procedure TForm1.FormCreate(Sender: TObject);
var SomeObject2: TSomeObject2;
begin
  SomeObject := TSomeObject.Create;
  //  SomeObject2 := TSomeObject2.Create(nil);        // ok
  SomeObject2 := TSomeObject2.Create(SomeObject);     // not ok
  try
  // do some things
  finally
    SomeObject2.Free;
  end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  SomeObject.Free; // if passed to a SomeObject2 Constructor - freeing it causing av
end;

メイン フォームを閉じると、AV とメモリ リークが発生します。メイン フォーム全体がリークしています。コンストラクターに渡す場合はnil、すべて問題ありません。TSomeObjectコンパイラは参照カウントによって解放されていますか? mainForm でFSomeInterface解放しようとすべきではありませんか? どうすれば回避できますか？SomeObjectdestructor

4

1 に答える 1

7

TSomeObject は TInterfacedObject から継承されるため、参照カウントされます。TSomeObject のインスタンスは参照カウントされないため、削除するかインターフェイス変数に置き換える必要があります。

FormCreate で作成された TSomeObject のインスタンスが必要な場合は、ISomeInterface 型の変数に割り当てる必要があります。これにより、参照カウントも機能します。

もう 1 つの方法は、TInterfacedObject の代わりに TInterfacedPersistant を継承して、参照カウントを回避することです。

コードで何が起こっているかを説明するには:

procedure TForm1.FormCreate(Sender: TObject);
var SomeObject2: TSomeObject2;
begin
  { Here you create the instance and assign it to a variable holding the instance.
    After this line the reference count of the instance is 0 }
  SomeObject := TSomeObject.Create;
  //  SomeObject2 := TSomeObject2.Create(nil);        // ok
  { Using the instance as a parameter will increase the reference count to 1 }
  SomeObject2 := TSomeObject2.Create(SomeObject);     // not ok
  try
  // do some things
  finally
    { Freeing SomeObject2 also destroys the interface reference FSomeInterface is
      pointing to (which is SomeObject), decreasing the reference count to 0, which
      in turn frees the instance of TSomeObject. }
    SomeObject2.Free;
  end;
  { Now, after SomeObject is freed, the variable points to invalid memory causing the
    AV in FormDestroy. }
end;
于 2013-04-29T07:21:37.013 に答える