0

Flickable.contentY の境界を尋ねる正しい方法は何ですか? スクロールバーに必要です。

実験的に私はそれを発見しました

offsetY <= contentY <= offsetY + contentHeight - height

ここで、offsetY は次のように計算できます。

var offsetY = contentY-Math.round(visibleArea.yPosition*contentHeight)

offsetY はアプリケーションの開始時にはゼロであり、Flickable のサイズが変更されない限り一定のようです。

この式は一般的に機能しますが、おそらく専用の関数が必要です。

4

1 に答える 1

5

オフセットなしで簡単にスクロールバーを作成しました:

// ScrollBar.qml
import QtQuick 2.0

Rectangle {
    id: scrollbar;
    color: "#3C3C3C";
    visible: (flicker.visibleArea.heightRatio < 1.0);
    property Flickable flicker : null;
    width: 20;
    anchors {
        top: flicker.top;
        right: flicker.right;
        bottom: flicker.bottom;
    }

    Rectangle {
        id: handle;
        height: (scrollbar.height * flicker.visibleArea.heightRatio);
        color: "#5E5E5E";
        border {
            width: 1;
            color: "white";
        }
        anchors {
            left: parent.left;
            right: parent.right;
        }

        Binding { // Calculate handle's x/y position based on the content position of the Flickable
            target: handle;
            property: "y";
            value: (flicker.visibleArea.yPosition * scrollbar.height);
            when: (!dragger.drag.active);
        }
        Binding { // Calculate Flickable content position based on the handle x/y position
            target: flicker;
            property: "contentY";
            value: (handle.y / scrollbar.height * flicker.contentHeight);
            when: (dragger.drag.active);
        }
        MouseArea {
            id: dragger;
            anchors.fill: parent;
            drag {
                target: handle;
                minimumX: handle.x;
                maximumX: handle.x;
                minimumY: 0;
                maximumY: (scrollbar.height - handle.height);
                axis: Drag.YAxis;
            }
        }
    }
}

次のように使用してください：

Flickable {
    id: myFlick;
}
ScrollBar { 
    flicker: myFlick;
}

マウスで移動でき、Flickable をスクロールすると自動的に移動します。

于 2013-05-28T11:50:25.337 に答える