ms-access - コマンド ラインから Access サーバー接続を変更する

Question

SQL Server 2008 バックエンドを使用する Access 2007 ADP アプリケーションを継承しました。アプリケーションが使用するサーバー接続をコマンド ラインまたは VBScript から変更することはできますか? 現時点では、アプリケーションをテスト/UAT/実稼働環境にリリースするときに、プロジェクトを開いてサーバー接続を変更し、再度保存する必要があります。

ビルド プロセスを可能な限り自動化しようとしていますが、現在、これは最後に残っている手動タスクの 1 つです。

Answer 1

うーん、私のGoogle-fuは弱いです。これを実現するための VBA スクリプトを提供する MSDN の記事を見つけました。以下のVBScriptとして実行するように変更しました。

Dim fso
Set fso = CreateObject("Scripting.FileSystemObject")

If (WScript.Arguments.Count = 0) Then
    WScript.Echo "ERROR - the Access project name must be specified"
    WScript.Quit()
End If

Dim sAccessProject
sAccessProject = fso.GetAbsolutePathName(WScript.Arguments(0))

If (fso.FileExists(sAccessProject) = False) Then
    WScript.Echo "ERROR - the Access project could not be located : " & sAccessProject
    WScript.Quit()
End If

If (WScript.Arguments.Count = 1) Then
    WScript.Echo "ERROR - the SQL Server hostname must be specified"
    WScript.Quit()
End If

Dim sServer
sServer = WScript.Arguments(1)

If (WScript.Arguments.Count = 2) Then
    WScript.Echo "ERROR - the SQL Server database name must be specified"
    WScript.Quit()
End If

Dim sDatabase
sDatabase = WScript.Arguments(2)

Dim sUsername
If (WScript.Arguments.Count = 3) Then
    sUsername = ""
Else
    sUsername = WScript.Arguments(3)
End If

Dim sPassword
If (WScript.Arguments.Count >= 3) Then
    sPassword = ""
Else
    sPassword = WScript.Arguments(4)
End If

ChangeADPConnection sAccessProject, sServer, sDatabase, sUsername, sPassword

Function ChangeADPConnection(strProjectName, strServerName, strDBName, strUN , strPW)

    Dim strConnect

    Dim oApplication
    Set oApplication = CreateObject("Access.Application")
    WScript.Echo "Starting MS Access"
    WScript.Echo "Opening " & strProjectName & " ..."
    oApplication.OpenAccessProject strProjectName
    oApplication.Visible = false

    oApplication.CurrentProject.CloseConnection

    'The Provider, Data Source, and Initial Catalog arguments are required.
    strConnect = "Provider=SQLOLEDB.1" & _
    ";Data Source=" & strServerName & _
    ";Initial Catalog=" & strDBName
    If strUN <> "" Then
        strConnect = strConnect & ";User ID=" & strUN
        If strPW <> "" Then
            strConnect = strConnect & ";Password=" & strPW
        End If
    Else  'Try to use integrated security if no username is supplied.
        strConnect = strConnect & ";Integrated Security=SSPI"
    End If

    WScript.Echo "Setting connection string to " & strConnect

    oApplication.CurrentProject.OpenConnection strConnect
    oApplication.Quit()
    Set oApplication = Nothing

End Function

実行するには、コマンドラインから次を使用します。

cscript connect.vbs Project.adp, "ServerName", "DatabaseName", "Username", "Password"