1

私は次のようなクラスを作成しました

TMyClass = class(TObject)
private
  FList1: TObjectList<List1>;
  FList2: TObjectList<List2>;
public
end;

今、FillArray(Content);できれば一度実装する必要がある method が必要です。つまり、オーバーロードはありません。これはジェネリックを使用して可能であると信じていますが、実際に実装するにはこれらの獣に慣れていません。誰か手がかりを持っていますか？前もって感謝します！

4

1 に答える 1

3

以下は、Delphi 2010 でのみ機能すると思われます。システム ユニットでの TArray<T> の宣言に依存するため、次のようになります。

  TArray<T> = array of T;

これは、TArray から List への変換を支援するために開発したユニットです。

unit ListTools;

interface                
uses Generics.Collections;
type
 TListTools = class(TObject)
 public
    // Convert TList<T> to TArray<T>
    class function ToArray<T>(AList: TList<T>): TArray<T>;
    // Append Array elements in AValues to AList
    class procedure AppendList<T>(AList : TList<T>;AValues : TArray<T>);
    // Clear List and Append Values to aList
    class procedure ToList<T>(AList : TList<T>;AValues : TArray<T>);
 end;

implementation

{ TListTools }

class procedure TListTools.AppendList<T>(AList: TList<T>; AValues: TArray<T>);
var
  Element : T;
begin
  for Element in AValues do
  begin
     AList.Add(Element);
  end;
end;

class function TListTools.ToArray<T>(AList: TList<T>): TArray<T>;
// taken from rtti.pas
var
  i : Integer;
begin
  SetLength(Result, AList.Count);
  for i := 0 to AList.Count - 1 do
    Result[i] := AList[i];
end;

class procedure TListTools.ToList<T>(AList: TList<T>; AValues: TArray<T>);
begin
   AList.Clear;
   AppendList<T>(AList,AValues);
end;

end.

TList<T> は TObjectList<T> の親クラスなので、試したことはありませんが、これは TObjectList<T> で動作するはずです。

于 2009-10-29T12:00:59.037 に答える