0

次のスクリプトを使用して、IIS および MySQL データ ディレクトリを SkyDrive フォルダーにバックアップしてからクラウドにアップロードしていますが、SkyDrive にはスペースまたは null 文字で始まるファイルに問題があり、正しくアップロードされません。

これらの特定の 2 つのファイルは、wordpress テーマの言語アドオンであるため気にしません。そのため、robocopy スクリプトから除外したいと思います。

どうすればいいですか？

@ECHO OFF
SETLOCAL

Set day=%DATE:~7,2%
Set mm=%DATE:~4,2%
Set dd=%DATE:~7,2%
Set yyyy=%DATE:~10,4%
Set RCLogFile=C:\BACKUP-SCRIPTS\logs\%yyyy%%mm%%dd%_-_FileSync-Log.txt

Set EmailLogFile=C:\BACKUP-SCRIPTS\logs\%yyyy%%mm%%dd%_-_Email-Log.txt
set EmailServer=mail.emailserver.com
set EmailFrom=support@mycompany.com.au
set EmailTo=user@mycompany.com.au
set EmailSubject=%~nx0: mycompany backup Results for %dd%%mm%%yyyy%
REM Optional; leave empty if the user running the task can send directly to the smtp server:
set EmailUser=
REM Because of passwords potentially containing characters with special meaning in batch,
REM the password string *has* to be enclosed in double quotes when setting the variable!
set EmailPass=""

SET _what=/COPYALL /B /MIR
 :: /COPYALL :: COPY ALL file info
 :: /B :: copy files in Backup mode. 
 :: /MIR :: MIRror a directory tree 

SET _options=/R:3 /W:10 /NDL /NP /TEE
 :: /R:n :: number of Retries
 :: /W:n :: Wait time between retries
 :: /LOG :: Output log file
 :: /LOG+ :: Append to existing Output log file
 :: /NDL :: No directory logging
 :: /NP :: No % percentage logging
 :: /XD :: exclude directories
 :: /XF :: exclude file(s)

net stop w3svc
net stop WAS
net stop MySQL

ROBOCOPY C:\inetpub D:\inetpub-backups\Friday %_what% %_options% /XD *file_hosting /XF *ar.* /LOG:"%RCLogFile%"
ROBOCOPY C:\ProgramData\MySQL D:\database-backups\offline\Friday %_what% %_options% /LOG+:"%RCLogFile%"

if "%EmailUser%"=="" (
    set LogonOption=
) else (
    set LogonOption= -u "%EmailUser%" -pw %EmailPass%
)
"C:\BACKUP-SCRIPTS\blat307\full\blat.exe" "%RCLogFile%" -server %EmailServer% -f %EmailFrom% -t %EmailTo% -s "%EmailSubject%" %LogonOption% >"%EmailLogFile%" 2>&1

net start MySQL
net start WAS
net start w3svc

ご覧のとおり、ワイルドカードを使用してファイルを除外して*ar.*いますが、拡張子が「ar」で終わるファイル (たとえば、hirecar.html) があった場合はどうなるでしょうか。


問題のあるファイルは「ar.mo」
「ar.po」 の 2 つだけです。

4

1 に答える 1

1

これを試して

ROBOCOPY C:\inetpub D:\inetpub-backups\Friday %_what% %_options% /XD *file_hosting /XF " ar.*" /LOG:"%RCLogFile%"

..またはこれ：

ROBOCOPY C:\inetpub D:\inetpub-backups\Friday %_what% %_options% /XD *file_hosting /XF " *ar.*" /LOG:"%RCLogFile%"

検索パターンにスペースが含まれる場合は、二重引用符で囲む必要があります。

于 2013-05-15T05:49:41.943 に答える