4

私は Delphi XE4 を 1 週間使用していますが、新しいTListGroups機能を発見しました。グループ間を簡単に切り替え/移動するように設定するTlistItemのは簡単です。ここで、グループを離れるとすぐに、および/またはグループに入るとGroupIDすぐに呼び出す手順が必要です。私はこのようなものを探しています:TListItemTlistItem

procedure TForm1.ListView1On(Before/After)ListGroupEnter(Sender: TObject; Item: TListItem);
begin
 // Do some stuff here like...
 // AllowedToDraw := TRUE/FALSE
 // I/O Code...
 // etc...
end;

procedure TForm1.ListView1On(Before/After)ListGroupLeave(Sender: TObject; Item: TListItem);
begin
 // Do some stuff here like...
 // This might be replaceable with OnDeletion...
 // I/O Code...
end;

GroupIDここでの主な問題は、プロパティを設定した場合にさまざまなグループ間の切り替えを検出することです。プロパティを変更/設定するとすぐにスイッチを検出するものはありGroupIDますか?

4

1 に答える 1

4

TListItem.GroupIDプロパティ セッターは、メッセージLVM_SETITEMをTListView'sHWND に送信します。をサブクラス化し、処理するTListView前にそのメッセージをインターセプトできます。次に例を示します。TListView

const
  APPWM_LISTVIEW_CHECKGROUP = WM_APP + 100;

var
  PrevLVWndProc: TWndMethod = nil;

procedure TForm1.FormCreate(Sender: TObject);
begin
  PrevLVWndProc := ListView1.WindowProc;
  ListView1.WindowProc := LVWndProc;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  ListView1.WindowProc := PrevLVWndProc;
end;

procedure TForm1.LVWndProc(var Message: TMessage);
var
  LVItem: PLVItem;
  ListItem: TListItem;
begin
  case Message.Msg of
    LVM_SETITEM:
    begin
      LVItem := PLVItem(Message.LParam);
      if (LVItem^.mask and LVIF_GROUPID) <> 0 then
      begin
        ListItem := ListView1.Items[LVItem.iItem];

        if ListItem.GroupID <> LVItem.iGroupID then
        begin
          if ListItem.GroupID >= 0 then
            ListView1GroupLeave(ListView1, ListItem);

          PrevLVWndProc(Message);

          // this gives the TListItem time to actually update itself
          PostMessage(ListView1.Handle, APPWM_LISTVIEW_CHECKGROUP, 0, LVItem.iItem);

          Exit;
        end;
      end;
    end;
    APPWM_LISTVIEW_CHECKGROUP:
    begin
      ListItem := ListView1.Items[Message.LParam];
      if ListItem.GroupID >= 0 then
        ListView1GroupEnter(ListView1, ListItem);
      Exit;
    end;
  end;

  PrevLVWndProc(Message);
end;

procedure TForm1.ListView1GroupLeave(Sender: TObject; Item: TListItem);
begin
  // Item is about to leave from its current GroupID ...
end;

procedure TForm1.ListView1GroupEnter(Sender: TObject; Item: TListItem);
begin
  // Item has entered into its current GroupID ...
end;
于 2013-05-15T16:17:53.373 に答える