186

カーソルを使用せずに、行の列がspへの入力パラメーターであるテーブルの各行のストアドプロシージャを呼び出すにはどうすればよいですか？

4

17 に答える 17

224

一般的に言って、私は常にセットベースのアプローチを探します（スキーマを変更することを犠牲にして）。

ただし、このスニペットにはその場所があります。

-- Declare & init (2008 syntax)
DECLARE @CustomerID INT = 0

-- Iterate over all customers
WHILE (1 = 1) 
BEGIN  

  -- Get next customerId
  SELECT TOP 1 @CustomerID = CustomerID
  FROM Sales.Customer
  WHERE CustomerID > @CustomerId 
  ORDER BY CustomerID

  -- Exit loop if no more customers
  IF @@ROWCOUNT = 0 BREAK;

  -- call your sproc
  EXEC dbo.YOURSPROC @CustomerId

END
于 2011-05-29T12:22:23.657 に答える
40

次のようなことができます。たとえば、CustomerID（AdventureWorksSales.Customerサンプルテーブルを使用）でテーブルを注文し、WHILEループを使用してそれらの顧客を反復処理します。

-- define the last customer ID handled
DECLARE @LastCustomerID INT
SET @LastCustomerID = 0

-- define the customer ID to be handled now
DECLARE @CustomerIDToHandle INT

-- select the next customer to handle    
SELECT TOP 1 @CustomerIDToHandle = CustomerID
FROM Sales.Customer
WHERE CustomerID > @LastCustomerID
ORDER BY CustomerID

-- as long as we have customers......    
WHILE @CustomerIDToHandle IS NOT NULL
BEGIN
    -- call your sproc

    -- set the last customer handled to the one we just handled
    SET @LastCustomerID = @CustomerIDToHandle
    SET @CustomerIDToHandle = NULL

    -- select the next customer to handle    
    SELECT TOP 1 @CustomerIDToHandle = CustomerID
    FROM Sales.Customer
    WHERE CustomerID > @LastCustomerID
    ORDER BY CustomerID
END

ORDER BYある列にある種のを定義できる限り、これはどのテーブルでも機能するはずです。

于 2009-11-01T10:44:30.487 に答える
31 
DECLARE @SQL varchar(max)=''

-- MyTable has fields fld1 & fld2

Select @SQL = @SQL + 'exec myproc ' + convert(varchar(10),fld1) + ',' 
                   + convert(varchar(10),fld2) + ';'
From MyTable

EXEC (@SQL)

さて、私はそのようなコードを本番環境に置くことは決してありませんが、それはあなたの要件を満たしています。

于 2012-12-14T22:32:26.473 に答える
14

受け入れられた答えを使用しますが、別の可能性は、テーブル変数を使用して番号付きの値のセット（この場合はテーブルのIDフィールドのみ）を保持し、行番号でそれらをループしてテーブルに結合することです。ループ内のアクションに必要なものをすべて取得します。

DECLARE @RowCnt int; SET @RowCnt = 0 -- Loop Counter

-- Use a table variable to hold numbered rows containg MyTable's ID values
DECLARE @tblLoop TABLE (RowNum int IDENTITY (1, 1) Primary key NOT NULL,
     ID INT )
INSERT INTO @tblLoop (ID)  SELECT ID FROM MyTable

  -- Vars to use within the loop
  DECLARE @Code NVarChar(10); DECLARE @Name NVarChar(100);

WHILE @RowCnt < (SELECT COUNT(RowNum) FROM @tblLoop)
BEGIN
    SET @RowCnt = @RowCnt + 1
    -- Do what you want here with the data stored in tblLoop for the given RowNum
    SELECT @Code=Code, @Name=LongName
      FROM MyTable INNER JOIN @tblLoop tL on MyTable.ID=tL.ID
      WHERE tl.RowNum=@RowCnt
    PRINT Convert(NVarChar(10),@RowCnt) +' '+ @Code +' '+ @Name
END
于 2014-09-24T14:39:26.013 に答える
12

マークの答えは良いです（方法がわかればコメントします！）ループを変更して1回だけ存在する
ように変更する方が良いかもしれないと指摘しただけです（実際には、SELECTこれを行うと、SELECT非常に複雑で、2回書き込むのはリスクの高いメンテナンスの問題でした）。

-- define the last customer ID handled
DECLARE @LastCustomerID INT
SET @LastCustomerID = 0
-- define the customer ID to be handled now
DECLARE @CustomerIDToHandle INT
SET @CustomerIDToHandle = 1

-- as long as we have customers......    
WHILE @LastCustomerID <> @CustomerIDToHandle
BEGIN  
  SET @LastCustomerId = @CustomerIDToHandle
  -- select the next customer to handle    
  SELECT TOP 1 @CustomerIDToHandle = CustomerID
  FROM Sales.Customer
  WHERE CustomerID > @LastCustomerId 
  ORDER BY CustomerID

  IF @CustomerIDToHandle <> @LastCustomerID
  BEGIN
      -- call your sproc
  END

END
于 2010-09-28T03:55:22.533 に答える
8

ストアドプロシージャをテーブルを返す関数に変換できる場合は、相互適用を使用できます。

たとえば、顧客のテーブルがあり、注文の合計を計算したい場合、CustomerIDを取得して合計を返す関数を作成します。

そして、あなたはこれを行うことができます：

SELECT CustomerID, CustomerSum.Total

FROM Customers
CROSS APPLY ufn_ComputeCustomerTotal(Customers.CustomerID) AS CustomerSum

関数は次のようになります。

CREATE FUNCTION ComputeCustomerTotal
(
    @CustomerID INT
)
RETURNS TABLE
AS
RETURN
(
    SELECT SUM(CustomerOrder.Amount) AS Total FROM CustomerOrder WHERE CustomerID = @CustomerID
)

明らかに、上記の例は、単一のクエリでユーザー定義関数なしで実行できます。

欠点は、関数が非常に制限されていることです。ストアドプロシージャの機能の多くはユーザー定義関数では使用できず、ストアドプロシージャを関数に変換しても常に機能するとは限りません。

于 2010-09-16T21:01:58.473 に答える
6

SQL Server 2005以降では、 CROSSAPPLYとテーブル値関数を使用してこれを行うことができます。

わかりやすくするために、ストアドプロシージャをテーブル値関数に変換できる場合を指します。

于 2009-11-01T10:31:19.620 に答える
4

これはすでに提供されている回答のバリエーションですが、ORDER BY、COUNT、またはMIN / MAXを必要としないため、パフォーマンスが向上するはずです。このアプローチの唯一の欠点は、すべてのIDを保持するための一時テーブルを作成する必要があることです（CustomerIDのリストにギャップがあることを前提としています）。

そうは言っても、私は@Mark Powellに同意しますが、一般的に言えば、セットベースのアプローチの方が優れているはずです。

DECLARE @tmp table (Id INT IDENTITY(1,1) PRIMARY KEY NOT NULL, CustomerID INT NOT NULL)
DECLARE @CustomerId INT 
DECLARE @Id INT = 0

INSERT INTO @tmp SELECT CustomerId FROM Sales.Customer

WHILE (1=1)
BEGIN
    SELECT @CustomerId = CustomerId, @Id = Id
    FROM @tmp
    WHERE Id = @Id + 1

    IF @@rowcount = 0 BREAK;

    -- call your sproc
    EXEC dbo.YOURSPROC @CustomerId;
END
于 2016-03-11T01:15:26.090 に答える
3

これは、上記のn3rdsソリューションのバリエーションです。MIN（）が使用されるため、ORDERBYを使用したソートは必要ありません。

CustomerID（または進行状況に使用するその他の数値列）には一意の制約が必要であることに注意してください。さらに、できるだけ速くするには、CustomerIDにインデックスを付ける必要があります。

-- Declare & init
DECLARE @CustomerID INT = (SELECT MIN(CustomerID) FROM Sales.Customer); -- First ID
DECLARE @Data1 VARCHAR(200);
DECLARE @Data2 VARCHAR(200);

-- Iterate over all customers
WHILE @CustomerID IS NOT NULL
BEGIN  

  -- Get data based on ID
  SELECT @Data1 = Data1, @Data2 = Data2
    FROM Sales.Customer
    WHERE [ID] = @CustomerID ;

  -- call your sproc
  EXEC dbo.YOURSPROC @Data1, @Data2

  -- Get next customerId
  SELECT @CustomerID = MIN(CustomerID)
    FROM Sales.Customer
    WHERE CustomerID > @CustomerId 

END

私は、最初に一時テーブルに配置してIDを与えることにより、調べる必要のあるいくつかのvarcharでこのアプローチを使用します。

于 2012-10-15T15:40:12.677 に答える
1

カーソルを使用する必要がない場合は、外部で実行する必要があると思います（テーブルを取得してから、ステートメントごとに実行し、spを呼び出すたびに）カーソルを使用するのと同じですが、外部でのみ実行しますSQL。なぜカーソルを使わないのですか？

于 2009-11-01T10:26:26.577 に答える
1

かなりの数の行がある場合、私は通常このようにします。

  1. SQLManagementStudioを使用してデータセット内のすべてのsprocパラメーターを選択します
  2. 右クリック->コピー
  3. 貼り付けてExcelに
  4. 新しいExcel列に'="EXEC schema.mysproc @ param ="＆A2'のような式を使用して単一行のSQLステートメントを作成します。（ここで、A2はパラメーターを含むExcel列です）
  5. ExcelステートメントのリストをSQLManagementStudioの新しいクエリにコピーして、実行します。
  6. 終わり。

（より大きなデータセットでは、上記のソリューションの1つを使用します）。

于 2011-03-21T10:35:24.580 に答える
1

区切り文字//

CREATE PROCEDURE setFakeUsers (OUT output VARCHAR(100))
BEGIN

    -- define the last customer ID handled
    DECLARE LastGameID INT;
    DECLARE CurrentGameID INT;
    DECLARE userID INT;

    SET @LastGameID = 0; 

    -- define the customer ID to be handled now

    SET @userID = 0;

    -- select the next game to handle    
    SELECT @CurrentGameID = id
    FROM online_games
    WHERE id > LastGameID
    ORDER BY id LIMIT 0,1;

    -- as long as we have customers......    
    WHILE (@CurrentGameID IS NOT NULL) 
    DO
        -- call your sproc

        -- set the last customer handled to the one we just handled
        SET @LastGameID = @CurrentGameID;
        SET @CurrentGameID = NULL;

        -- select the random bot
        SELECT @userID = userID
        FROM users
        WHERE FIND_IN_SET('bot',baseInfo)
        ORDER BY RAND() LIMIT 0,1;

        -- update the game
        UPDATE online_games SET userID = @userID WHERE id = @CurrentGameID;

        -- select the next game to handle    
        SELECT @CurrentGameID = id
         FROM online_games
         WHERE id > LastGameID
         ORDER BY id LIMIT 0,1;
    END WHILE;
    SET output = "done";
END;//

CALL setFakeUsers(@status);
SELECT @status;
于 2012-05-30T18:06:51.217 に答える
1

これに対するより良い解決策は

  1. ストアドプロシージャのコピー/過去のコード
  2. そのコードを、（行ごとに）再度実行するテーブルに結合します

これは、クリーンなテーブル形式の出力を取得したことです。一方、すべての行に対してSPを実行すると、反復ごとに個別のクエリ結果が得られますが、これは見苦しいものです。

于 2016-12-13T09:59:14.450 に答える
0

順序が重要な場合

--declare counter
DECLARE     @CurrentRowNum BIGINT = 0;
--Iterate over all rows in [DataTable]
WHILE (1 = 1)
    BEGIN
        --Get next row by number of row
        SELECT TOP 1 @CurrentRowNum = extendedData.RowNum
                    --here also you can store another values
                    --for following usage
                    --@MyVariable = extendedData.Value
        FROM    (
                    SELECT 
                        data.*
                        ,ROW_NUMBER() OVER(ORDER BY (SELECT 0)) RowNum
                    FROM [DataTable] data
                ) extendedData
        WHERE extendedData.RowNum > @CurrentRowNum
        ORDER BY extendedData.RowNum

        --Exit loop if no more rows
        IF @@ROWCOUNT = 0 BREAK;

        --call your sproc
        --EXEC dbo.YOURSPROC @MyVariable
    END
于 2016-03-14T12:27:30.347 に答える
0

一度に20人の従業員しか処理できない本番コードがいくつかありました。以下は、コードのフレームワークです。プロダクションコードをコピーして、以下のものを削除しました。

ALTER procedure GetEmployees
    @ClientId varchar(50)
as
begin
    declare @EEList table (employeeId varchar(50));
    declare @EE20 table (employeeId varchar(50));

    insert into @EEList select employeeId from Employee where (ClientId = @ClientId);

    -- Do 20 at a time
    while (select count(*) from @EEList) > 0
    BEGIN
      insert into @EE20 select top 20 employeeId from @EEList;

      -- Call sp here

      delete @EEList where employeeId in (select employeeId from @EE20)
      delete @EE20;
    END;

  RETURN
end
于 2016-12-20T19:12:51.983 に答える
0

結果セット（テーブル）に対して一連の操作を実行する必要がある状況がありました。操作はすべてセット操作なので問題ありませんが…複数の場所で行う必要がありました。したがって、関連する部分をテーブルタイプに入れてから、各結果セットを含むテーブル変数を設定すると、spを呼び出して、必要なたびに操作を繰り返すことができます。

これは彼が尋ねる正確な質問には対応していませんが、カーソルを使用せずにテーブルのすべての行に対して操作を実行する方法に対応しています。

@Johannesは彼の動機についての洞察を提供していないので、これは彼を助けるかもしれないし、助けないかもしれません。

私の調査は、私のソリューションの基礎として役立つこのよく書かれた記事に私を導きました https://codingsight.com/passing-data-table-as-parameter-to-stored-procedures/

これがセットアップです

    drop type if exists cpRootMapType 
go 

create type cpRootMapType as Table(
    RootId1 int 
    , RootId2 int
)

go 
drop procedure if exists spMapRoot2toRoot1
go 
create procedure spMapRoot2toRoot1
(
@map cpRootMapType Readonly
)
as

update linkTable set root = root1  
from linktable  lt 
join @map m on lt.root = root2

update comments set root = root1 
from comments c 
join @map m on c.root = root2

--  ever growing list of places this map would need to be applied....
--  now consolidated into one place

これが実装です

... populate #matches

declare @map cpRootMapType 
insert @map select rootid1, rootid2 from #matches
exec spMapRoot2toRoot1 @map
于 2020-12-11T18:31:03.897 に答える
-1

私はこれに似た何かをするのが好きです（それでもカーソルの使用に非常に似ていますが）

[コード]

-- Table variable to hold list of things that need looping
DECLARE @holdStuff TABLE ( 
    id INT IDENTITY(1,1) , 
    isIterated BIT DEFAULT 0 , 
    someInt INT ,
    someBool BIT ,
    otherStuff VARCHAR(200)
)

-- Populate your @holdStuff with... stuff
INSERT INTO @holdStuff ( 
    someInt ,
    someBool ,
    otherStuff
)
SELECT  
    1 , -- someInt - int
    1 , -- someBool - bit
    'I like turtles'  -- otherStuff - varchar(200)
UNION ALL
SELECT  
    42 , -- someInt - int
    0 , -- someBool - bit
    'something profound'  -- otherStuff - varchar(200)

-- Loop tracking variables
DECLARE @tableCount INT
SET     @tableCount = (SELECT COUNT(1) FROM [@holdStuff])

DECLARE @loopCount INT
SET     @loopCount = 1

-- While loop variables
DECLARE @id INT
DECLARE @someInt INT
DECLARE @someBool BIT
DECLARE @otherStuff VARCHAR(200)

-- Loop through item in @holdStuff
WHILE (@loopCount <= @tableCount)
    BEGIN

        -- Increment the loopCount variable
        SET @loopCount = @loopCount + 1

        -- Grab the top unprocessed record
        SELECT  TOP 1 
            @id = id ,
            @someInt = someInt ,
            @someBool = someBool ,
            @otherStuff = otherStuff
        FROM    @holdStuff
        WHERE   isIterated = 0

        -- Update the grabbed record to be iterated
        UPDATE  @holdAccounts
        SET     isIterated = 1
        WHERE   id = @id

        -- Execute your stored procedure
        EXEC someRandomSp @someInt, @someBool, @otherStuff

    END

[/コード]

一時/変数テーブルのIDまたはisIterated列は必要ないことに注意してください。ループを繰り返すときに、コレクションから最上位のレコードを削除する必要がないように、この方法を使用することをお勧めします。

于 2013-04-23T20:02:47.297 に答える