3

学校のプロジェクトのために、Mac (10.7) で .asm ファイルを実行しようとしています。しかし、私は実際にそれを実行する方法を理解していないようです。ターミナルから実行できることはわかっていますが、どうすればよいですか？

または、実際に .asm ファイルを実行するには xcode を使用する必要がありますか? または、アセンブリ コードを手動で別の形式に変換する必要がありますか?

参考までに、実行しようとしているプログラムは

# ************************************************************************
# * Program name : sieve *
# * Description : this program prints all the prime numbers below 1000 *
# ************************************************************************
.bss
NUMBERS: .skip 1000 # memory space for the number table
.text
formatstr: .asciz "%d\n" # format string for number printing
.global main
# ************************************************************************
# * Subroutine : main *
# * Description : application entry point *
# ************************************************************************
   main: movl %esp, %ebp # initialize the base pointer 
   # Initialize the number table:
   movl $0, %eax # initialize 'i' to 0.
   loop1: movb $1, NUMBERS(%eax) # set number table entry 'i' to 'true'
   incl %eax # increment 'i'
   cmpl $1000, %eax # while 'i' < 1000
   jl loop1 # go to start of loop1
   # The sieve algorithm:
   pushl $2 # initialize 'number' to 2 on stack   
   loop2: movl -4(%ebp), %eax # load 'number' into a register
   cmpb $1, NUMBERS(%eax) # compare NUMBERS[number] to '1'
   jne lp2end # if not equal, jump to end of loop 2
   pushl $formatstr # push the format string for printing
   call printf # print the number
   addl $4, %esp # pop the format string
   movl -4(%ebp), %eax # 'multiple' := 'number'
   shl $1, %eax # multiply 'multiple' by 2
   loop3: cmp $1000, %eax # compare 'multiple' to 1000
   jge lp2end # goto end of loop2 if greater/equal
   movb $0, NUMBERS(%eax) # set number table entry to 'false'
   addl -4(%ebp), %eax # add another 'number' to 'multiple'
   jmp loop3 # jump to the beginning of loop 3
   lp2end: movl -4(%ebp), %eax # load 'number' into a register
   incl %eax # increment 'number' by one
   movl %eax, -4(%ebp) # store 'number' on the stack
   cmpl $1000, %eax # compare 'number' to 1000
   jl loop2 # if smaller, repeat loop2
   end: movl $0,(%esp) # push program exit code
   call exit # exit the program
4

2 に答える 2

1

これをコマンド ライン ( Macのターミナルsieve.Sアプリケーション内) でビルドして実行するには、ファイルを保存して次のようにします。

$ clang -m32 -g sieve.S -o sieve
$ ./sieve 
2
3
5
<...>

これを Xcode でオフハンドでビルドする方法がわかりません。空のプロジェクトを作成sieve.Sし、ソース ファイルとして追加するだけで機能する場合があります。

于 2013-05-27T14:00:56.723 に答える