actionscript-3 - 引数付きの Flash AS3 イベント関数

Question

渡すパラメーターを持つイベント関数を作成する必要があります。これは次のようになります。

    public function foo(e:Event, args)
    {
        trace(args[0]);
    }


    addEventListener("fooEvent", foo);
    dispatchEvent(new Event("fooEvent", true), args);

とにかく、私はこれを行うことができますか？みんなありがとう。

Answer 1

これを試して：

package {
  import flash.events.Event;

  public class CustomEvent extends Event {
    public var params:Object;

    public function CustomEvent(type:String, paramsObj:Object = null, bubbles:Boolean = true, cancelable:Boolean = true) {
      super(type, bubbles, cancelable);

      if (paramsObj) {
        params = paramsObj;
      }
    }

    public override function clone():Event{
      return new CustomEvent(type, params, bubbles, cancelable);
    }

    public override function toString():String{
      return formatToString("CustomEvent", "params", "type", "bubbles", "cancelable");
    }
  }
}

その後、次のようにイベントを構成できます。

dispatchEvent(new CustomEvent("fooEvent", {param1:"foo", param2:"bar"}))

そして、次のようなデータを取得します。

addEventListener("fooEvent", function(event:CustomEvent):void {
  trace("param1: " + event.params.param1);
  trace("param2: " + event.params.param2);
});