vba - 現在ログインしている Windows ユーザーを取得する

Question

Google経由でこれを見つけました：http://www.mvps.org/access/api/api0008.htm

'******************** Code Start **************************
' This code was originally written by Dev Ashish.
' It is not to be altered or distributed,
' except as part of an application.
' You are free to use it in any application,
' provided the copyright notice is left unchanged.
'
' Code Courtesy of
' Dev Ashish
'
Private Declare Function apiGetUserName Lib "advapi32.dll" Alias _
    "GetUserNameA" (ByVal lpBuffer As String, nSize As Long) As Long

Function fOSUserName() As String
' Returns the network login name
Dim lngLen As Long, lngX As Long
Dim strUserName As String
    strUserName = String$(254, 0)
    lngLen = 255
    lngX = apiGetUserName(strUserName, lngLen)
    If ( lngX > 0 ) Then
        fOSUserName = Left$(strUserName, lngLen - 1)
    Else
        fOSUserName = vbNullString
    End If
End Function
'******************** Code End **************************

これが最善の方法ですか？

Answer 1

これを行うこともできます：

Set WshNetwork = CreateObject("WScript.Network")
Print WshNetwork.UserName

また、UserDomainプロパティと他の多くのものがあります。

http://msdn.microsoft.com/en-us/library/907chf30(VS.85).aspx

Answer 2

Environ$ を使用することもできますが、質問で指定された方法の方が優れています。ユーザー/アプリケーションは環境変数を変更できます。

Answer 3

私は通常、次のようにVBA内から環境を使用します。ケンが可能性として言及している問題はありません。

Function UserNameWindows() As String
    UserNameWindows = VBA.Environ("USERNAME") & "@" & VBA.Environ("USERDOMAIN")
End Function

Answer 4

それを行う別の方法-おそらくあなたが言及したAPIはユーザー名を取得するためのより良い方法です。

For Each strComputer In arrComputers
    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    Set colItems = objWMIService.ExecQuery("Select * from Win32_ComputerSystem",,48)
        For Each objItem in colItems
        Wscript.Echo "UserName: " & objItem.UserName & " is logged in at computer " & strComputer
Next

Answer 5

他の投稿には多くの代替方法がありますが、質問に答えるには: はい、それが最善の方法です。ユーザー名だけが必要な場合は、COM オブジェクトまたは WMI を作成するよりも高速で、Win95 から Windows のすべてのバージョンで使用できます。