4

私は次のperlサブルーチンを持っています:

sub rep {

 defined ($filein = shift) || die ("no filein");
 defined ($fileout = shift) || die ("no fileout");
 $look = shift;
 $replace = shift;
 open (infile, "$filein")|| die;
 open (outfile, "> $fileout")|| die;
 while (<infile>) {
   s/$look/$replace/g;
   print outfile;
 }
(close the files)
}

および次のテキスト:

kuku(fred) foo(3)
kuku(barney) foo(198)

私は次の構造でそれを呼び出したい:

$look = kuku\((\w+)\) foo \((\d+)\),
$replace = gaga\(($1)\) bar\(($2)\).

しかし、次の (およびそのバリエーション) でサブを呼び出したとき、$1、$2 形式を受け入れるようにできませんでした:

&rep ($ARGV[0], $ARGV[1], 
    "kuku\\(\(\\w+\)\\) foo \\(\(\\d+\)\\)" , 
    "gaga\\(\(\$1\)\\) bar\\(\(\$2\)\\)");

私が得るのは次のとおりです。

gaga($1) bar($2)
gaga($1) bar($2)

私は何を間違っていますか？検索と置換の検索結果としてサブルーチンに $1\ $2 (...) を特定させるにはどうすればよいですか?

4

1 に答える 1

7

eval を使用せずに正規表現の置換部分を希望どおりに設定できるかどうかわからない/eので、このように記述します。

qr//パラメータは実際の正規表現であり、その後にコールバックが続きます$_[0]。$1

rep( $ARGV[0], $ARGV[1], qr/kuku\((\w+)\) foo \((\d+)\)/, sub { "gaga($_[0]) bar($_[1])" } );

sub rep {

  my ($filein, $fileout, $look, $replace) = @_;
  defined $filein or die "no filein";
  defined $fileout or die "no fileout";

  open (my $infile, "<", $filein) or die $!;
  open (my $outfile, ">", $fileout) or die $!;

  while (<$infile>) {
    s/$look/$replace->($1,$2)/ge;
    print $outfile;
  }
  # (close the files)
}

これは、変更されるコールバックを渡すだけでさらに簡素化できます$_。

rep( $ARGV[0], $ARGV[1], sub { s|kuku\((\w+)\) foo \((\d+)\)|gaga($1) bar($2)| } );

sub rep {

  my ($filein, $fileout, $replace) = @_;
  defined $filein or die "no filein";
  defined $fileout or die "no fileout";

  open (my $infile, "<", $filein) or die $!;
  open (my $outfile, ">", $fileout) or die $!;

  while (<$infile>) {
    $replace->();
    print $outfile;
  }
  # (close the files)
}
于 2013-06-03T08:47:41.643 に答える