vb.net - スレッドがスリープしている間にキープレスを「リッスン」する

Question

画面に UI を表示せずにこれを行う方法はありますか? 現在、この小さな非 UI プログラムに 3270 メインフレームからテキスト ファイルへの情報の読み取りと書き込みを 60 秒ごとに実行させています。ユーザーが 60 秒待機の途中でキャンセルしたいとします。 UIからのイベントなしでキーを押しますか?

Answer 1

キーストロークをキャプチャするには、何らかのインターフェイスが必要です。

コンソール アプリケーションで実行する例を次に示します (空白のアプリケーションを作成し、defauklt モジュールに貼り付けます)。

ユーザーがコマンドを入力できるように GUI をアイドル状態にしたまま、バックグラウンド スレッドで「SOMETHING」を処理できます。この場合、1000 までの単純な 1 秒の遅延カウンターです。

オプション比較テキスト

Module Module1

Sub Main()
    Console.WriteLine("Enter ""Start"", ""Stop"", or ""Exit"".")
    Do
        Dim Com As String = Console.ReadLine
        Select Case Com
            Case "Start"
                Console.WriteLine(StartWork)
            Case "Stop"
                Console.WriteLine(StopWork)
            Case "Exit"
                Console.WriteLine("Quiting on completion")
                Exit Do
            Case Else
                Console.WriteLine("bad command Enter ""Start"", ""Stop"", or ""Exit"".")
        End Select
    Loop
End Sub

Public Function StartWork() As String
    If ThWork Is Nothing Then
        ThWork = New Threading.Thread(AddressOf Thread_Work)
        ThWork.IsBackground = False  'prevents killing the work if the user closes the window.
        CancelWork = False
        ThWork.Start()
        Return "Started Work"
    Else
        Return "Work Already Processing"
    End If
End Function

Public Function StopWork() As String
    CancelWork = True
    If ThWork Is Nothing Then
        Return "Work not currently running"
    Else
        Return "Sent Stop Request"
    End If
End Function

Public CancelWork As Boolean = False
Public ThWork As Threading.Thread = Nothing
Public dummyCounter As Integer = 0

Public Sub Thread_Work()
    Try
        Do
            dummyCounter += 1
            Console.Title = "Working ... #" & dummyCounter
            ' ###############
            ' do a SMALL PART OF YOUR WORK here to allow escape...
            ' ###############
            If dummyCounter >= 1000 Then
                Console.Title = "Work Done at #" & dummyCounter
                Exit Do
            ElseIf CancelWork Then
                Exit Do
            End If
            Threading.Thread.Sleep(1000) ' demo usage only.
        Loop
    Catch ex As Exception
        Console.WriteLine("Error Occured at #" & dummyCounter)
    End Try
    ThWork = Nothing
    If CancelWork Then
        Console.Title = "Work Stopped at #" & dummyCounter
    End If
End Sub

End Module