3

趣味として、イーサネットに接続された LED サインをプログラミングして、画面上でメッセージをスクロールすることに興味があります。しかし、 VB.NETで UDP 送信者を作成するのに問題があります(現在 2008 を使用しています)。

現在、標識は、プログラミングに関する仕様書を作成するのに十分なほど優れています。

しかし、それに送信する行の例 (3 ページ):

<0x01>Z30<0x02>AA<0x06><0x1B>0b<0x1C>1<0x1A>1This message will show up on the screen<0x04>

16 進文字を表す <0x01> などのコードを使用します。

これを署名に送信するには、UDPを使用する必要があります。ただし、次のように、送信する前にメッセージをASCIIとしてエンコードした例はすべて（ UDPから：クライアントはサーバーにパケットを送信し、サーバーからパケットを受信します）：

Imports System.Threading
Imports System.Net.Sockets
Imports System.IO
Imports System.Net


Public Class MainClass
   Shared Dim client As UdpClient
   Shared Dim receivePoint As IPEndPoint


   Public Shared Sub Main()
      receivePoint = New IPEndPoint(New IPAddress(0), 0)
      client = New UdpClient(8888)
      Dim thread As Thread = New Thread(New ThreadStart(AddressOf WaitForPackets))
      thread.Start()


         Dim packet As String = "client"
         Console.WriteLine("Sending packet containing: ")

         '
         ' Note the following line below, would appear to be my problem.
         '

         Dim data As Byte() = System.Text.Encoding.ASCII.GetBytes(packet)
         client.Send(data, data.Length, "localhost", 5000)
         Console.WriteLine("Packet sent")

   End Sub

   Shared Public Sub WaitForPackets()
      While True
         Dim data As Byte() = client.Receive(receivePoint)
         Console.WriteLine("Packet received:" & _
            vbCrLf & "Length: " & data.Length & vbCrLf & _
            System.Text.Encoding.ASCII.GetString(data))

      End While

   End Sub ' WaitForPackets

End Class

VB.NET で 16 進コードを出力するには、構文が &H1A である可能性があると思います - 仕様で定義されているものを <0x1A> として送信します。

そのコードを変更して、正しくフォーマットされたパケットをこの標識に正しく送信できますか?

Grant (16 進数を含むパケットを送信した後)、Hamish Smith (関数を使用して 16 進数値を取得)、および Hafthor (例にハードコードされた chr() メッセージ) からの回答は、すべてが機能しませんでした。だから、他に何がうまくいかないかを調べるために調査します。理論的には、この文字列が正常に送信された場合、"OK" を含むメッセージが返されるはずです。これは、いつ機能したかを知るのに役立ちます。

試してみたところ、通過するパケットを監視できるようになりました。動作するパケットの例は次のとおりです (生の 16 進数): http://www.brettjamesonline.com/misc/forums/other/working.raw vs 私のバージョン: http://www.brettjamesonline.com/misc/forums/other /failed.raw . 違いは、私の 16 進コードがまだ正しくエンコードされていないことです。

このコードを使用して、パケットを生成して送信しました。

container = &H1 & "Z" & &H30 & &H2 & "temp.nrg" & &H1C & "1Something" & &H4
    '    This did not appear to work neither
    'container = Chr(&H1) & "Z" & Chr(&H30) & Chr(&H2) & Chr(&H1C) & "1Something" & Chr(&H4)
    '<0x01>Z00<0x02>FILENAME<0x1C>1Test to display<0x04>   <- the "official" spec to send
Dim sendBytes As [Byte]() = Encoding.ASCII.GetBytes(container)

(完全なスニペット: http://pastebin.com/f44417743 .)

4

4 に答える 4

2

次のような急ごしらえのデコーダーをまとめることができます。

Function HexCodeToHexChar(ByVal m as System.Text.RegularExpressions.Match) As String
    Return Chr(Integer.Parse(m.Value.Substring("<0x".Length, 2), _
         Globalization.NumberStyles.HexNumber))
End Function

次に、これを使用して変換します。

Dim r As New System.Text.RegularExpressions.Regex("<0x[0-9a-fA-F]{2}>")
Dim s As String = r.Replace("abc<0x44>efg", AddressOf HexCodeToHexChar)
' s should now be "abcDefg"

このデコードを元に戻すエンコーダー関数を作成することもできます（少し複雑ですが）

Function HexCharToHexCode(ByVal m As Match) As String
    If m.Value.StartsWith("<0x") And m.Value.EndsWith(">") And m.Value.Length = "<0x??>".Length Then
        Return "<0<0x78>" + m.Value.Substring("<0x".Length)
    ElseIf Asc(m.Value) >= 0 And Asc(m.Value) <= &HFF Then
        Return "<0x" + Right("0" + Hex(Asc(m.Value)), 2) + ">"
    Else
        Throw New ArgumentException("Non-SBCS ANSI characters not supported")
    End If
End Function

これを使用して変換します。

Dim r As New Regex("[^ -~]|<0x[0-9a-fA-F]{2}>")
Dim s As String = r.Replace("abc"+chr(4)+"efg", AddressOf HexCharToHexCode)
' s should now be "abc<0x04>efg"

または、次のように、特殊文字を含む文字列を作成することもできます。

Dim packet As String = Chr(&H01) + "Z30" + Chr(&H02) + "AA" + Chr(&H06) + _
    Chr(&H1B) + "0b" + Chr(&H1C) + "1" + Chr(&H1A) + _
    "1This message will show up on the screen" + Chr(&H04)

UDPパケットを送信するには、以下で十分です。

Dim i As New IPEndPoint(IPAddress.Parse("192.168.0.5"), 3001) ''//Target IP:port
Dim u As New UdpClient()
Dim b As Byte() = Encoding.UTF8.GetBytes(s) ''//Where s is the decoded string
u.Send(b, b.Length, i)
于 2008-10-04T00:36:05.213 に答える
0

これは役立つかもしれません。私の会社では、ASCIIと16進数の組み合わせを使用してハードウェアと通信する必要があります。

この関数を使用して、IPアドレスをハードウェアに送信する前に16進数化します

Public Function HexFromIP(ByVal sIP As String)
    Dim aIP As String()
    Dim sHexCode As String = ""
    aIP = sIP.Split(".")

    For Each IPOct As String In aIP
        sHexCode += Hex(Val(IPOct)).PadLeft(2, "0")
    Next

    Return sHexCode
End Function

そして時々私も使用hexSomething = Hex(Val(number)).PadLeft(2,"0")します。

さまざまなハードウェアと通信するように設計されていますが、プログラム全体のソースも提供できます。

編集：

パケットを16進数で送信しようとしていますか、それともパケットを16進数で取得しようとしていますか？

于 2008-10-04T00:28:40.580 に答える
0

UDPクライアントはバイトの配列を送信します。
メモリストリームを使用して、配列にバイトを書き込むことができます。 

Public Class MainClass
   Shared client As UdpClient
   Shared receivePoint As IPEndPoint


   Public Shared Sub Main()
      receivePoint = New IPEndPoint(New IPAddress(0), 0)
      client = New UdpClient(8888)
      Dim thread As Thread = New Thread(New ThreadStart(AddressOf WaitForPackets))
      thread.Start()


      Dim packet As Packet = New Packet("client")
      Console.WriteLine("Sending packet containing: ")
      Dim data As Byte() = packet.Data

      client.Send(data, data.Length, "localhost", 5000)
      Console.WriteLine("Packet sent")

   End Sub

   Public Shared Sub WaitForPackets()
      While True
         Dim data As Byte() = client.Receive(receivePoint)
         Console.WriteLine("Packet received:" & _
            vbCrLf & "Length: " & data.Length & vbCrLf & _
            System.Text.Encoding.ASCII.GetString(data))

      End While

   End Sub ' WaitForPackets  

End Class  

Public Class Packet  
   Private _message As String  

   Public Sub New(ByVal message As String)
      _message = message
   End Sub

   Public Function Data() As Byte()

      Dim ret(13 + _message.Length) As Byte

      Dim ms As New MemoryStream(ret, True)

      ms.WriteByte(&H1)

      '<0x01>Z30<0x02>AA<0x06><0x1B>0b<0x1C>1<0x1A>1This message will show up on the screen<0x04>  
      ms.Write(System.Text.Encoding.ASCII.GetBytes("Z30"), 0, 3)

      ms.WriteByte(&H2)

      ms.Write(System.Text.Encoding.ASCII.GetBytes("AA"), 0, 2)

      ms.WriteByte(&H6)

      ms.Write(System.Text.Encoding.ASCII.GetBytes("0b"), 0, 2)

      ms.WriteByte(&H1C)

      ms.Write(System.Text.Encoding.ASCII.GetBytes("1"), 0, 1)

      ms.WriteByte(&H1A)

      ms.Write(System.Text.Encoding.ASCII.GetBytes(_message), 0, _message.Length)

      ms.WriteByte(&H4)

      ms.Close()

      Data = ret
   End Function
End Class
于 2008-10-04T00:47:47.000 に答える
0

彼らは、Visual Basic を含む多数の言語のライブラリを (別のファイルで) 投稿しました。サインの 1 つを使用してデモをテストしたところ、動作しました。

http://support.favotech.com

于 2009-05-02T08:28:55.637 に答える