1 
@Echo off
:: Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
:: If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
Echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
Echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
Echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
Exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( Del "%temp%\getadmin.vbs" )
Pushd "%CD%"
CD /D "%~dp0"
C:\Windows\System32\notepad.exe C:\Windows\System32\drivers\etc\hosts

上記のバッチ ファイルを使用して、ホスト ファイルを編集しています。Windows 7 では、デフォルトで UAC プロンプトは表示されません。だから私はこれを使いました。ただし、ユーザーがホスト ファイルを編集するための管理者権限を持っていない場合、if ループが継続的に実行され、ログオフするかシステムを再起動する必要があるプロセスを停止します。

バッチ ファイルが 1 回か 2 回だけ実行され、管理者権限を取得していない場合は終了するように、誰でもバッチ ファイルの変更を提案できます。

ありがとうシバスンダール

4

2 に答える 2

1

スクリプトが自己起動されたかどうかを知らせるパラメータをスクリプトに追加します。スクリプトが自己起動され、管理者権限がない場合は終了します。

@echo off
setlocal EnableExtensions

set "VBS=%Temp%\getadmin.vbs"

:: Check for permissions
>nul 2>&1 "%SystemRoot%\System32\cacls.exe" "%SystemRoot%\System32\config\system"
if "%ErrorLevel%"=="0" goto gotAdmin
if /i "%~1"=="Self" exit /b 1
goto UACPrompt


:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%VBS%"
echo UAC.ShellExecute "%~s0", "Self %*", "", "runas", 1 >> "%VBS%"
echo Requesting administrative privileges...
"%VBS%"
exit /b 1


:gotAdmin
shift
if exist "%VBS%" del "%VBS%"
pushd "%CD%"
cd /d "%~dp0"
"%SystemRoot%\System32\notepad.exe" "%SystemRoot%\System32\drivers\etc\hosts"
popd
endlocal

アップデート：

@echo off
setlocal EnableExtensions

set "ExitCode=0"
set "VBS=%Temp%\getadmin.vbs"

:: Check for permissions
>nul 2>&1 "%SystemRoot%\System32\cacls.exe" "%SystemRoot%\System32\config\system"
if "%ErrorLevel%"=="0" goto gotAdmin
if /i "%~1"=="Self" goto ElevateFail
goto UACPrompt


:ElevateFail
set "ExitCode=1"
echo Error: Administrator privileges are required.
pause>nul
goto End


:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%VBS%"
echo UAC.ShellExecute "%~s0", "Self %*", "", "runas", 1 >> "%VBS%"
echo Requesting administrative privileges...
"%VBS%"
goto End


:gotAdmin
shift
if exist "%VBS%" del "%VBS%"
pushd "%CD%"
cd /d "%~dp0"
"%SystemRoot%\System32\notepad.exe" "%SystemRoot%\System32\drivers\etc\hosts"
popd


:End
endlocal & exit /b %ExitCode%
于 2013-06-06T14:32:28.663 に答える
0

:PAUSEコードの最後で を使用します。

@Echo off
:: Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
:: If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
Echo Requesting administrative privileges...
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
Echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
Echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
Exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( Del "%temp%\getadmin.vbs" )
Pushd "%CD%"
CD /D "%~dp0"
C:\Windows\System32\notepad.exe C:\Windows\System32\drivers\etc\hosts
:PAUSE
于 2013-06-06T08:39:45.327 に答える