12

任意のキーを持つネストされた JSON オブジェクトがたくさんあります。

{
    "A": {
        "B": {
            "C": "hello"

        }
    }

}

A、B、は事前Cに不明です。これら 3 人のそれぞれに兄弟がいる可能性もあります。

これをAesonでエレガントな方法でカスタムタイプに解析する方法があるかどうか疑問に思っています。私がやっていることは、それを Aeson にロードすることですObject。

FromJSONこの種の JSON オブジェクトをどのように実装しますか?

ありがとう！

編集：

{
    "USA": {
        "California": {
            "San Francisco": "Some text"
        }
    },
    "Canada": {
        ...
    }
}

これはどこにコンパイルする必要がCountryDatabaseあります...

type City            = Map String String
type Country         = Map String City
type CountryDatabase = Map String Country
4

1 に答える 1

18

FromJSONのインスタンスを再利用できますMap String v。次のようなもの：

{-# LANGUAGE OverloadedStrings #-}

import Data.Functor
import Data.Monoid
import Data.Aeson
import Data.Map (Map)
import qualified Data.ByteString.Lazy as LBS
import System.Environment

newtype City = City (Map String String)
  deriving Show

instance FromJSON City where
  parseJSON val = City <$> parseJSON val

newtype Country = Country (Map String City)
  deriving Show

instance FromJSON Country where
  parseJSON val = Country <$> parseJSON val

newtype DB = DB (Map String Country)
  deriving Show

instance FromJSON DB where
  parseJSON val = DB <$> parseJSON val

main :: IO ()
main = do
  file <- head <$> getArgs
  str <- LBS.readFile file
  print (decode str :: Maybe DB)

出力：

shum@shum-lt:/tmp/shum$ cat in.js 
{
    "A": {
        "A1": {
            "A11": "1111",
            "A22": "2222"
        }
    },
    "B": {
    }
}
shum@shum-lt:/tmp/shum$ runhaskell test.hs in.js 
Just (DB (fromList [("A",Country (fromList [("A1",City (fromList [("A11","1111"),("A22","2222")]))])),("B",Country (fromList []))]))
shum@shum-lt:/tmp/shum$

PS: newtypes なしで実行できます。わかりやすくするためにのみ使用しました。

于 2013-06-24T18:12:48.150 に答える