1

コマンドラインと ImageMagic を初めていじった後、次のことができるようになりました。

c:\test\paper.pdf contains a pdf file
c:\test>convert paper.pdf output-%d.tiff

ファイルには 5 つのページが含まれており、出力は予想どおり 5 つの tiff ファイルです :-) ここで、複数のファイルを入れてそれらをループし、元のファイル名に基づいてページを作成しpdfたいと考えています。c:\testに次のファイルがあるとしますc:\test。

paper.pdf     (5 pages)
example.pdf   (2 pages)
new.pdf       (1 page)

c:\test\tiffs\バッチ スクリプトの出力は、フォルダー内の 8 つの tiff ファイルである必要があります。

paper-0.tiff paper-1.tiff paper-2.tiff paper-3.tiff paper-4.tiff
example-0.tiff example-1.tiff
new-0.tiff

そして、コマンドラインがpdfをtiffに変換するのにかかった時間を返すことを非常に望んでいます:

c:\test>convert.bat
c:\test>This action took 120 seconds

このバッチファイルを書き込もうとしていますが、初めての試みなのでうまくいきません。私は最初にtestフォルダーをループしてすべての tiff を作成しようとしています (今のところプロセスのタイミングを残します)。

for %%f in (C:\test\) do convert %%f.pdf %%f-%%d.tiff

これが機能することを期待していましたが、エラーが発生しました：

C:\Users\Me>convert c:\test\c:\test\.pdf c:\test\c:\test\-%d.tiff convert.exe: 
unable to open image `c:\test\c:\test\.pdf': Invalid argument @ 
error/blob.c/OpenBlob/2646. convert.exe: no decode delegate for this image 
format `c:\test\c:\test\.pdf' @ error/constitute.c/ReadImage/552. convert.exe: 
no images defined `c:\test\c:\test\-%d.tiff' @ 
error/convert.c/ConvertImageCommand/3106.

私は何を間違っていますか？

4

1 に答える 1

2

タイミング

これは、バッチ/CMD を使用して実行するのが間違っている (実際には、見せびらかすために実行しても問題ありません) ジョブの 1 つです。私がこれまでに遭遇したほぼすべてのプログラミング言語は、CMD よりもこれを行うのに適しています。

この特定の (ハックな) 実装は、経過時間が任意の日の午前 0 時を過ぎた場合は機能しません。また、ロケールでの日付の構成方法によっては、実行が午後 1 時より前に開始され、午後 1 時以降に終了すると機能しなくなる可能性があります。

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

FOR /F "tokens=5 delims= " %%t IN ('^<NUL time') DO SET START_TIME=%%t

:: Stuff that you're timing.

FOR /F "tokens=5 delims= " %%t IN ('^<NUL time') DO SET END_TIME=%%t

SET ELAPSED=
FOR /F "delims=:. tokens=1,2,3,4" %%a IN ("%START_TIME%") DO (
    FOR /F "delims=:. tokens=1,2,3,4" %%n IN ("%END_TIME%") DO (
        SET /A HOURS=%%n-%%a
        SET /A MINUTES=%%o-%%b
        SET /A SECONDS=%%p-%%c
        SET /A HUND=%%q-%%d

        SET /A TOTAL=!HOURS!*3600 + !MINUTES!*60 + !SECONDS!
        IF !HUND! LSS 0 (
            SET /A TOTAL=!TOTAL!-1
            SET /A HUND=!HUND!+100
        )
        IF !HUND! LSS 10 SET HUND=0!HUND!

        SET ELAPSED=!TOTAL!.!HUND!
    )
)

@ECHO.
@ECHO.
@ECHO This action took %ELAPSED% seconds.

イメージマジック

あなたのコマンドで私が目にする問題convertは、検索するパターンを CMD に伝えていないことです。みたいですね*.pdf。これを行うと、入力ファイル名の末尾に「.pdf」を追加する必要がなくなり、出力ファイル名を指定するときに拡張子を削除する必要がなくなります。は%%~dpnf、拡張子を除いたファイルへの完全なパスを生成します。

FOR %%f IN (C:\temp\*.pdf) do convert "%%~f" "%%~dpnf-%%d.tiff"

編集: PDF を別の場所に配置するには、%%f置換を変更します。

FOR %%f IN (C:\temp\*.pdf) do convert "%%~f" "\path\to\tiffs\%%~nf-%%d.tiff"

より良い方法？

少なくとも、Right™ の方法でそれを行うためのプラグインを挿入する必要があると思います。タイミングをサポートする言語 (Python など) のスクリプトからコマンドを呼び出したくない場合は、システム時間を整数として取得できます。この戦略は、およそ 2038 年まで機能します。この例では Perl を使用しました。

@ECHO OFF

FOR /F %%t IN ('perl -e "print(time());"') DO SET START_TIME=%%t

:: stuff to time

FOR /F %%t IN ('perl -e "print(time());"') DO SET END_TIME=%%t
SET /A ELAPSED=%END_TIME%-%START_TIME%
@ECHO This step took %ELAPSED% seconds.
于 2013-06-27T16:34:43.473 に答える