1

Google ブックマークをコピーして、「ブックマークのバックアップ」と呼ばれる別のフォルダ (バックアップのようなもの) に貼り付けるバッチ ファイルを作成しています。一日の終わりに毎日スクリプトを実行して、いつでもバックアップできるようにしたかったので（スケジュールされたタスクにすることができます）、新しいフォルダーを作成するコマンドを挿入しました（backupというフォルダー内）ブックマークの）「バックアップ」と呼ばれ、スクリプトが実行されるたびに「1」ずつ増加します（例：backup1; backup2;など）。コピーしたばかりのファイルを取得して、インクリメント フォルダーに貼り付ける方法を教えてください。これがスクリプトです。フォルダーをコピーしてインクリメントしますが、コピーしたファイルをインクリメントされたフォルダーに入れる方法がわかりません。

::this script backs up your Chrome bookmarks. 
::Checks to see if the folder exits and makes a new folder incremented by 1

@echo off
setlocal enableDelayedExpansion
set "baseName=Backup"
set "n=0"
for /f "delims=" %%F in (
    '2^>nul dir /b /ad "%baseName%*."^|findstr /xri "%baseName%[0-9]*"'
) do (
    set "name=%%F"
    set "name=!name:*%baseName%=!"
    if !name! gtr !n! set "n=!name!"
)
set /a n+=1
md "%baseName%%n%"


xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks"  "C:\Users\jnicholas\Desktop\backup of bookmarks\"
pause

xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks.bak"  "C:\Users\jnicholas\Desktop\backup of bookmarks"
pause

move /y | /-y "C:\Users\jnicholas\Desktop\backup of bookmarks\bookmarks" "C:\Users\jnicholas\Desktop\backup of bookmarks\"%baseName%%n%""
4

2 に答える 2

0

XP Pro 以降を使用している場合、これにより、バックアップ用の日付と時刻がスタンプされたフォルダーが作成されます。日付と時刻の形式は、PC のローカル地域設定とは無関係です。

@echo off
for /f "delims=" %%a in ('wmic OS Get localdatetime  ^| find "."') do set dt=%%a
set datestamp=%dt:~0,8%
set timestamp=%dt:~8,6%
set YYYY=%dt:~0,4%
set MM=%dt:~4,2%
set DD=%dt:~6,2%
set HH=%dt:~8,2%
set Min=%dt:~10,2%
set Sec=%dt:~12,2%

set stamp=%YYYY%-%MM%-%DD%_%HH%-%Min%-%Sec%
echo stamp: "%stamp%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"

xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks"  "C:\Users\jnicholas\Desktop\backup of bookmarks\%stamp%\"

xcopy "C:\Users\jnicholas\AppData\Local\Google\Chrome\User Data\Default\bookmarks.bak"  "C:\Users\jnicholas\Desktop\backup of bookmarks\%stamp%\"
pause
于 2013-07-04T09:45:59.143 に答える