0

共通の値を見つけて特定のパターンを書き込み、範囲パターンに減算するシェル スクリプト

2 つのファイルでコマンド値を取得し、ia パターンを新しいファイルに書き込み、かつ範囲パターンの最初の値を 1 減算するシェル スクリプト

$ cat file1
2
3
4
6
7
8
10
12
13
16
20
21
22
23
27
30

$ cat file2
2
3
4
8
10
12
13
16
20
21
22
23
27

動作するスクリプト:

awk 'NR==FNR{x[$1]=1} NR!=FNR && x[$1]' file1 file2 | sort | awk 'NR==1 {s=l=$1; next} $1!=l+1 {if(l == s) print l; else print s ":" l; s=$1} {l=$1} END {if(l == s) print l; else print s ":" l; s=$1}'

スクリプトアウト:

2:4
8
10
12:13
16
20:23
27

Desired output:

1:4
8
10
11:13
16
19:23
27
4

2 に答える 2

2

commファイルの内容の交差を見つけるために使用することを除いて、sputnick のものに似ています。

comm -12 <(sort file1) <(sort file2) | 
sort -n |
awk '
    function print_range() {
        if (start != prev) 
            printf "%d:", start-1
        print prev
    }
    FNR==1 {start=prev=$1; next} 
    $1 > prev+1 {print_range(); start=$1}
    {prev=$1}
    END {print_range()}
'

1:4
8
10
11:13
16
19:23
27
于 2013-07-08T20:21:35.570 に答える
1

これをやってみてください：

awk 'NR==FNR{x[$1]=1} NR!=FNR && x[$1]' file1 file2 |
    sort |
    awk 'NR==1 {s=l=$1; next}
        $1!=l+1 {if(l == s) print l; else print s -1  ":" l; s=$1}
        {l=$1}
        END {if(l == s) print l; else print s -1 ":" l; s=$1}'
于 2013-07-08T19:33:03.997 に答える