1

XSLT を使用して xml をスラッシュ区切りのテキスト ファイルに変換しています。私のxmlの一部で、次のものを作成する必要があります。 

HEADING
/1    /2                   /3       /4     /5 /6        /7
/data /data                /data    /dat   / 1/data     /data

見出しがあり、数字は列のタイトルで、その下にデータ行があります。各列の間隔は同じである必要がありますが、データの長さは列間に必要なスペースより短くてもかまいません。これを使用して値を取得しています：

<xsl:value-of select="package_identification"/>

余ったスペースを空白で埋めるにはどうすればよいですか?

4

2 に答える 2

1

考えられる方法を2つ紹介します。

XML 入力

<test>
    <row>
        <entry>data</entry>
        <entry>dataaaa</entry>
        <entry>data</entry>     
    </row>
    <row>
        <entry>datadata</entry>
        <entry>datad</entry>
        <entry>da</entry>       
    </row>
</test>

最初の XSLT 2.0

これは、リテラル スペースを使用して列幅を表します。また、substring()不要なものを取り除くために使用します...

<xsl:stylesheet version="2.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="colwidths" as="element()">
        <colwidths>
            <col val="                 "/>                 
            <col val="         "/>
            <col val="                       "/>                         
        </colwidths>
    </xsl:variable>

    <xsl:template match="row">
        <xsl:apply-templates/>
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>

    <xsl:template match="entry">
        <xsl:variable name="currPos" select="position()"/>
        <xsl:value-of select="concat('/',.,substring($colwidths/col[$currPos]/@val,string-length(.)))"/>
    </xsl:template>

</xsl:stylesheet>

2 番目の XSLT 2.0

これは似ていますが、数字を使用して列幅を表し、xsl:for-each必要なスペースを出力するために使用します...

<xsl:stylesheet version="2.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="colwidths" as="element()">
        <colwidths>
            <col val="17"/>                 
            <col val="9"/>
            <col val="23"/>                         
        </colwidths>
    </xsl:variable>

    <xsl:template match="row">
        <xsl:apply-templates/>
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>

    <xsl:template match="entry">
        <xsl:variable name="currPos" select="position()"/>
        <xsl:value-of select="concat('/',.)"/>
        <xsl:for-each select="0 to xs:integer($colwidths/col[$currPos]/@val - string-length(.))">
            <xsl:text> </xsl:text>
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

これらは両方とも、次の出力を生成します。

/data              /dataaaa   /data                    
/datadata          /datad     /da
于 2013-07-11T04:09:47.533 に答える
0

EXSLT を使用できる場合は、str:padding 関数を使用してください: http://www.exslt.org/str/functions/padding/index.html

列の幅を 10 文字にしたいと仮定すると、XSLT の行から次のように作業します。

<xsl:value-of select="package_identification"/>
<xsl:value-of select="str:padding(10 - string-length(package_identification))"/>

できれば xsl:stylesheet 要素で xmlns:str="http://exslt.org/strings" を宣言してください。

EXSLT を使用できない場合は、再帰的なパディング テンプレートを定義します。

<xsl:template name="padding">
  <xsl:param name="length"/>
  <xsl:param name="string" select="' '"/>
  <xsl:value-of select="$string"/>
  <xsl:if test="$length > 1">
    <xsl:call-template name="padding">
      <xsl:with-param name="length" select="$length - 1"/>
      <xsl:with-param name="string" select="$string"/>
    </xsl:call-template>
  </xsl:if>
</xsl:template>

次に、次のように使用します。

<xsl:value-of select="package_identification"/>
<xsl:call-template name="padding">
  <xsl:with-param name="length" select="10 - string-length(package_identification)"/>
</xsl:call-template>
于 2013-07-11T04:41:09.090 に答える