2

CTEでSPを書きました。

CREATE PROC [dbo].[CategoryListShow]
 @id AS INT
 AS
WITH CategoryList
AS
(
  SELECT parent.Categoryid, CONVERT(varchar(50),parent.CategoryName)
  as
  Name, parent.CategoryParentid
  FROM Category as parent
  WHERE parent.CategoryParentid IS NULL

  UNION ALL

  SELECT child.Categoryid, CONVERT(varchar(50),CL.Name + ' > ' + child.CategoryName)
   as Name, child.CategoryParentid
   FROM Category as child

   INNER JOIN CategoryList as CL ON child.CategoryParentid = CL.Categoryid

   WHERE child.CategoryParentid IS NOT NULL
)
   SELECT Name from CategoryList option (maxrecursion 0)

どうすれば目的の出力を達成できますか? たとえば、ユーザーが入力した場合id = 14111、出力は次のようになります。 Everything Else > Test Auctions > General

私のテーブル構造:

ありがとう

4

1 に答える 1

2

あなたはこれを行うことができます

;with
CTE_Data as 
(
    select C.CategoryID, cast(C.CategoryName as nvarchar(max)) as CategoryName
    from Category as C
    where C.CategoryID = C.CategoryParentId

    union all

    select C.CategoryID, CD.CategoryName + ' > ' + C.CategoryName
    from Category as C
        inner join CTE_Data as CD on CD.CategoryID = C.CategoryParentId
    where C.CategoryID <> C.CategoryParentId
)
select * 
from CTE_Data
where CategoryID = @ID

またはその逆：

;with
CTE_Data as 
(
    select C.CategoryID, cast(C.CategoryName as nvarchar(max)) as CategoryName, C.CategoryParentId
    from Category as C
    where C.CategoryID = @ID

    union all

    select C.CategoryID,  cast(C.CategoryName as nvarchar(max)) + ' > ' + CD.CategoryName, C.CategoryParentId
    from Category as C
      inner join CTE_Data as CD on CD.CategoryParentId = C.CategoryID
    where CD.CategoryID <> C.CategoryID
)
select CategoryName
from CTE_Data
where CategoryID = CategoryParentId

SQL フィドル

于 2013-07-11T12:59:18.450 に答える