1

処理中に単純なビデオ遅延を発生させるのに非常に問題があります。私はインターネットを見回しましたが、同じコードを見つけ続けていて、まったく動作しません。私が最初に試したとき、何もしませんでした（まったく）。これが私の変更されたバージョンです（少なくともフレームをバッファにロードするようです）、なぜそれが機能しないのか本当にわかりません。髪を抜くのに本当に疲れています。お願い...お願い、神様の愛のために、誰か私がここで犯している愚かな間違いを指摘してください。そして今、さらに遅れることなく (ハァッ、わかりますか?)、コードは次のとおりです。

import processing.video.*;

VideoBuffer vb;
Movie myMovie;
Capture cam;

float seconds = 1;

void setup() {
  size(320,240, P3D);
  frameRate(30);

  String[] cameras = Capture.list();

  if (cameras.length == 0) {
    println("There are no cameras available for capture.");
    exit();
  } else {
    println("Available cameras:");
    for (int i = 0; i < cameras.length; i++) {
      println(cameras[i]);
    }
  cam = new Capture(this, cameras[3]);
  cam.start(); 

  }

  vb = new VideoBuffer(90, width, height);

}

void draw() {

  if (cam.available() == true) {
    cam.read();
    vb.addFrame(cam);
  }

  image(cam, 0, 0);
  image( vb.getFrame(), 150, 0 );

}  



class VideoBuffer
{
  PImage[] buffer;

  int inputFrame = 0;
  int outputFrame = 0;
  int frameWidth = 0;
  int frameHeight = 0;

  VideoBuffer( int frames, int vWidth, int vHeight )
  {
    buffer = new PImage[frames];
    for(int i = 0; i < frames; i++)
    {
  this.buffer[i] = new PImage(vWidth, vHeight);
    }
    this.inputFrame = 0;
    this.outputFrame = 1;
    this.frameWidth = vWidth;
    this.frameHeight = vHeight;
  }

  // return the current "playback" frame.  
  PImage getFrame()
  {
    return this.buffer[this.outputFrame];
  } 

  // Add a new frame to the buffer.
  void addFrame( PImage frame )
  {
    // copy the new frame into the buffer.
    this.buffer[this.inputFrame] = frame;

    // advance the input and output indexes
    this.inputFrame++;
    this.outputFrame++;
    println(this.inputFrame + " " + this.outputFrame);

    // wrap the values..    
    if(this.inputFrame >= this.buffer.length)
    {
 this.inputFrame = 0;
    }
    if(this.outputFrame >= this.buffer.length)
    {
  this.outputFrame = 0;
    }
  }  
}
4

1 に答える 1

3

これは Processing 2.0.1 で機能します。

import processing.video.*;

Capture cam;
PImage[] buffer;
int w = 640;
int h = 360;
int nFrames = 60;
int iWrite = 0, iRead = 1;

void setup(){
  size(w, h);
  cam = new Capture(this, w, h);
  cam.start();
  buffer = new PImage[nFrames];
}

void draw() {
  if(cam.available()) {
    cam.read();
    buffer[iWrite] = cam.get();
    if(buffer[iRead] != null){
      image(buffer[iRead], 0, 0);
    }
    iWrite++;
    iRead++;
    if(iRead >= nFrames-1){
      iRead = 0;
    }
    if(iWrite >= nFrames-1){
      iWrite = 0;
    }
  }       
}

addFrame-Method内に問題があります。ピクセルが常に上書きされる PImage オブジェクトへの参照を保存するだけです。buffer[inputFrame] = frame.get()の代わりに使用する必要がありbuffer[inputFrame] = frameます。このget()メソッドは、イメージのコピーを返します。

于 2013-07-18T11:09:40.273 に答える