0

Word 2010 に次のマクロがあります。マクロを実行するときに値 1 (コペンハーゲン) を事前選択したいので、コペンハーゲンが事前選択されたドキュメントにコンテンツ コントロールのドロップダウン リストを配置します。

これを行うにはどうすればよいですか?:

Sub Cities()
'
' Cities Macro
'
'
Selection.Range.ContentControls.Add (wdContentControlDropdownList)
Selection.ParentContentControl.Title = "Cities"
Selection.ParentContentControl.LockContentControl = False
Selection.ParentContentControl.DropdownListEntries.Add Text:="Copenhagen", Value:="1"
Selection.ParentContentControl.DropdownListEntries.Add Text:="New York", Value:="2"
Selection.ParentContentControl.DropdownListEntries.Add Text:="London", Value:="3"
Selection.ParentContentControl.DropdownListEntries.Add Text:="Paris", Value:="4"
Selection.MoveRight Unit:=wdCharacter, Count:=1
End Sub

前もって感謝します！

/ アンダース H.

4

2 に答える 2

0

ドキュメントを勉強しましたか？これは Word 2013 用ですが、このページの 2010 バージョンよりも詳細です。

Sub Cities()
    '
    ' Cities Macro
    '
    '
    Dim objCC As ContentControl
    Dim objCE As ContentControlListEntry

    Set objCC = Selection.Range.ContentControls.Add(wdContentControlDropdownList)
    With objCC
        .Title = "Cities"
        .LockContentControl = False
        '.DropdownListEntries.Add Text:="Copenhagen", Value:="1"
        Set objCE = .DropdownListEntries.Add("Copenhagen", "1")
        objCE.Select
        'or
        '.DropdownListEntries.Add("Copenhagen", "1").Select

        .DropdownListEntries.Add Text:="New York", Value:="2"
        .DropdownListEntries.Add Text:="London", Value:="3"
        .DropdownListEntries.Add Text:="Paris", Value:="4"
    End With
    'Selection.MoveRight Unit:=wdCharacter, Count:=1
    'Selection is no longer in the document range
End Sub

これは、Selectコペンハーゲンを選択する方法を使用します。ただし、Selection がドキュメント範囲内にないことを意味します。次のようなものを使用できます。

ActiveDocument.Characters(1).Select

（または他の何百万もの方法..）カーソルをドキュメント範囲に戻し、コペンハーゲンを選択したままにします。

于 2013-07-17T22:02:18.403 に答える